Re: This is easy! Windows binary -> proxifier -> proxy server -> VPN server -> ISP -> Internet

Marion wrote:
> This is just too easy to chain encryptions in a ladder-like sequence!
> a. binary -> proxifier -> proxy server -> VPN server -> ISP -> Internet
> b. Internet -> VPN server -> proxy server -> proxifier -> binary
> Woo hoo! It can be done!

UPDATE

One problem PG&E introduced to the equation though, is when the power 
suddenly fails (which, here in California, happens about once a month)
the system registry and Wi-Fi adaptor can be left in an unknown state.

When the desktop unexpectedly dies, upon reboot, there is not Internet.

I worked around that problem with the following script, that I donate so 
that others can either improve it or that they can make good use of it.

It's initiated with "Win+R > netconnect" (using App Paths registry keys).

  @echo off
  REM C:\data\sys\batch\netconnect.bat 20251029
  REM This is v1p0
  REM Resets Wi-Fi to a consistent state after unexpected loss 
  REM  elevates to admin 
  REM  toggles Wi-Fi to put it into a consistent state after reboot
  REM  then connects to a given named SSID 
  REM v1p1
  REM  added conditional checks
  
  :: --- Elevate to admin if not already ---
  >nul 2>&1 net session
  if %errorlevel% neq 0 (
      echo Requesting administrative privileges...
      powershell -Command "Start-Process '%~f0' -Verb RunAs"
      exit /b
  )
  
  :: Use "netsh interface show interface" to get adapter name
  set adapter=Wi-Fi
  set ssid=your.SSID_nomap

  :: The saved SSID profile is used for credentials.
  netsh interface show interface name=%adapter%
  
  REM Disable the adapter (to set to a consistent state)
  netsh interface set interface name=%adapter% admin=disable
  timeout /t 5 >nul
  
  REM Enable the adapter (to set to the desired state)
  netsh interface set interface name=%adapter% admin=enable
  timeout /t 10 >nul
  
  echo Attempting to connect to %ssid%...
  
  REM Connect to the specified SSID after adapter is fully enabled
  powershell -Command "Enable-NetAdapter -Name '%adapter%' -Confirm:$false"
  timeout /t 5 >nul
  
  set retries=2
  :retry
  netsh wlan connect name=%ssid%
  timeout /t 5 >nul
  netsh wlan show interfaces | findstr /C:"State" /C:"SSID" >nul
  
  if %errorlevel% neq 0 (
      set /a retries-=1
      if %retries% gtr 0 (
          echo Retrying connection to %ssid%...
          goto retry
      ) else (
          echo Connection failed after multiple attempts.
      )
  ) else (
      echo Connected successfully to %ssid%.
  )
  
  echo [%date% %time%] Done. Check your connection status.
  echo Final adapter status:
  netsh interface show interface name=%adapter%
  netsh wlan show interfaces
  pause
  :: end of C:\data\sys\batch\netconnect.bat
-- 
Usenet is where kind-hearted well-educated people gather to exchange ideas.