Re: Pbind question

One easy solution would be to send the notes to a synth that uses Lag.ar 
or VarLag.ar on its frequency argument, and use Pmono instead of Pbind.

Pmono ensures that the same running synth is updated as opposed to 
creating a new synth for every new note.

Then you don't need to do anything special to have a glissando.

Very simple example:

(
s.waitForBoot({
     var player;

     SynthDef(\gliss, {
         var freq = \freq.ar(440);
         var amp = \amp.kr(0.1);
         var out = \out.kr(0);
         var lagTime = \lagTime.kr(1);
         Out.ar(out, amp*LFSaw.ar(Lag.ar(in:freq, lagTime:lagTime))!2);
     }).add;

     player = Pmono(
         \gliss,
         \out, 0,
         \midinote, Pseq([60, 67, 72, 65, 63], inf),
         \dur, Pseq([1, 1, 1, 0.5, 0.5], inf),
         \lagTime, Pseq([1.9, 0.9, 1.9, 0.3, 0.1], inf),
         \amp, 0.05
     ).play;

});
)



On 6/3/21 8:51 PM, [email protected] wrote:
> Hey everyone,
> I was wondering how I'd make a smooth upward or downward slide from
> one note to another. I'm using Pseries right now, but even with a
> large legato value and small step value, it sounds choppy. I hear
> notes like this in 8-bit music a lot, so I know the end result, but
> don't know how to replicate it.
>
> Thanks in advance.
>
> _______________________________________________
> sc-users mailing list
>
> info (subscription, etc.): http://www.birmingham.ac.uk/facilities/ea-studios/research/supercollider/mailinglist.aspx
> archive: http://www.listarc.bham.ac.uk/marchives/sc-users/
> search: http://www.listarc.bham.ac.uk/lists/sc-users/search/

_______________________________________________
sc-users mailing list

info (subscription, etc.): http://www.birmingham.ac.uk/facilities/ea-studios/research/supercollider/mailinglist.aspx
archive: http://www.listarc.bham.ac.uk/marchives/sc-users/
search: http://www.listarc.bham.ac.uk/lists/sc-users/search/