Re: Python bindings using cppyy (was: An update on Python bindings)

cmake_minimum_required(VERSION 3.9)

find_package(Cppyy)
find_package(ECM REQUIRED NO_MODULE)
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR} ${ECM_MODULE_PATH})
include(FeatureSummary)
include(FindPkgConfig)
include(CMakeFindDependencyMacro)

#
# Find the targets and dependencies for a KDE component.
#
set(_DEPENDENCIES)
function(get_kf5_info component)
    find_dependency(${component})
    set(real_targets)
    set(real_dependencies)
    #
    # Loop over all cmake files.
    #
    set(file_glob  ${${component}_DIR}/*.cmake)
    file(GLOB files ${file_glob})
    foreach(f ${files})
        #
        # Targets.
        #
        file(STRINGS ${f} matches REGEX "^ *add_library\\(.*\\) *")
        if(NOT matches STREQUAL "")
            foreach(target ${matches})
                string(REGEX REPLACE " *add_library\\(([^ \\)]+).*" "\\1" target ${target})
                if(TARGET ${target})
                    list(APPEND real_targets ${target})
                    list(REMOVE_DUPLICATES real_targets)
                else()
                    message(STATUS "Ignoring invalid target \"${target}\" for ${component} in ${f}")
                endif()
            endforeach()
        endif()
        #
        # Dependencies.
        #
        file(STRINGS ${f} matches REGEX "^ *find_dependency\\(.*\\) *")
        if(NOT matches STREQUAL "")
            foreach(dependency ${matches})
                string(REGEX REPLACE " *find_dependency\\(([^ \\)]+).*" "\\1" dependency ${dependency})
                if(NOT ${dependency} STREQUAL "")
                    list(APPEND real_dependencies ${dependency})
                    list(REMOVE_DUPLICATES real_dependencies)
                    #
                    # Recurse...if we have not been here before.
                    #
                    string(FIND ${dependency} "KF5" found)
                    if(found EQUAL 0 AND NOT dependency IN_LIST _DEPENDENCIES)
                        get_kf5_info(${dependency})
                        list(APPEND real_dependencies ${dependencies})
                        list(REMOVE_DUPLICATES real_dependencies)
                    endif()
                else()
                    message(STATUS "Ignoring invalid dependency \"${dependency}\" for ${component} in ${f}")
                endif()
            endforeach()
        endif()
    endforeach()
    set(targets "${real_targets}" PARENT_SCOPE)
    set(dependencies "${real_dependencies}" PARENT_SCOPE)
endfunction(get_kf5_info)

#
# Find the targets and dependencies for a Qt component.
#
function(get_qt5_info component)
    find_dependency(${component} NO_MODULE)
    #
    # Targets.
    #
    string(REPLACE "Qt5" "Qt5::" target ${component})
    if(NOT TARGET ${target})
        message(STATUS "Ignoring invalid target \"${target}\" for ${component}")
        set(target "")
    endif()
    set(targets "${target}" PARENT_SCOPE)
    #
    # Dependencies.
    #
    set(dependencies "" PARENT_SCOPE)
endfunction(get_qt5_info)

#
# Fetch a target property, recursing if necessary.
#
function(get_target_property_recursive target property)
    set(result)
    get_target_property(values ${target} ${property})
    if(values STREQUAL "values-NOTFOUND")
        # Skip
        # message(STATUS "Warning: Target ${target} has no property ${property}")
    else()
        foreach(value ${values})
            string(FIND ${value} "$<TARGET_PROPERTY:" found)
            if(found EQUAL 0)
                #
                # Recurse. The format is:
                #
                # $<TARGET_PROPERTY:KF5::WebKit,INTERFACE_INCLUDE_DIRECTORIES>
                #
                string(REGEX REPLACE "\\$<TARGET_PROPERTY:(.*),(.*)>" "\\1" nested_tgt ${value})
                string(REGEX REPLACE "\\$<TARGET_PROPERTY:(.*),(.*)>" "\\2" nested_prop ${value})
                get_target_property_recursive(${nested_tgt} ${nested_prop})
                list(APPEND result ${get_target_property_recursive_result})
            else()
                list(APPEND result ${value})
            endif()
        endforeach()
    endif()
    set(get_target_property_recursive_result "${result}" PARENT_SCOPE)
endfunction(get_target_property_recursive)

#
# Find the includes, libraries etc. for a component.
#
function(get_targets_info component targets)
    if(targets STREQUAL "")
        message(STATUS "Warning: No targets for ${component}")
        return()
    endif()
    #
    # Make a combined list of includes, libraries etc.
    #
    # There is a potential impedence mismatch between the directory-centric
    # Pythonic notion of a package, and the possibility that the the multiple
    # targets *might* have conflicting options. Luckily, this seems not to be
    # a problem in KF5.
    #
    set(libraries)
    set(includes)
    set(compile_flags)
    foreach(target ${targets})
        if(TARGET ${target})
            get_target_property(tmp ${target} LOCATION)
            list(APPEND libraries ${tmp})
            get_target_property_recursive(${target} INTERFACE_INCLUDE_DIRECTORIES)
            list(APPEND includes ${get_target_property_recursive_result})
            get_target_property_recursive(${target} INTERFACE_COMPILE_DEFINITIONS)
            foreach(definition ${get_target_property_recursive_result})
                if(${definition} MATCHES ".*QT_NO_DEBUG>")
                    #
                    # Qt uses the formulation "$<$<NOT:$<CONFIG:Debug>>:QT_NO_DEBUG>".
                    #
                elseif(${definition} MATCHES "QT_.*_LIB")
                    #
                    # Qt uses the formulation "QT_CORE_LIB" even for INTERFACE_COMPILE_FLAGS.
                    #
                else()
                    list(APPEND compile_flags "-D${definition}")
                endif()
            endforeach()
            get_target_property_recursive(${target} INTERFACE_COMPILE_OPTIONS)
            list(APPEND compile_flags ${get_target_property_recursive_result})
        else()
            message(STATUS "Warning: Ignoring invalid target \"${target}\" in ${f}")
        endif()
    endforeach()
    #
    # De-duplicate and write results.
    #
    if(DEFINED includes)
        list(REMOVE_DUPLICATES includes)
        #
        # Not sure why the headers seem to include this.
        #
        list(REMOVE_ITEM includes "/usr/include")
    endif()
    if(DEFINED compile_flags)
        list(REMOVE_DUPLICATES compile_flags)
    endif()
    set(libraries "${libraries}" PARENT_SCOPE)
    set(includes "${includes}" PARENT_SCOPE)
    set(compile_flags "${compile_flags}" PARENT_SCOPE)
endfunction(get_targets_info)

#
# Find the includes, libraries etc. for a pkg-config component.
#
function(get_pkgconfig_info component)
    set(libraries)
    set(includes ${${component}_INCLUDEDIR})
    set(compile_flags ${${component}_CFLAGS})
    foreach(tmp ${${component}_LIBRARIES})
        find_library(lib${tmp} NAMES ${tmp} PATHS ${${component}_LIBRARIES})
        list(APPEND libraries ${lib${tmp}})
    endforeach()
    set(libraries "${libraries}" PARENT_SCOPE)
    set(includes "${includes}" PARENT_SCOPE)
    set(compile_flags "${compile_flags}" PARENT_SCOPE)
endfunction(get_pkgconfig_info)


#
# Return the information required to create the bindings for a set of KF5 components.
#
#   get_kf5_binding_info(
#       COMPONENTS components
#       DEPENDENCIES extras)
#
# Arguments and options:
#
#   COMPONENTS component
#                       The CMake packages to include in the bindings.
#
#   DEPENDENCIES dependency
#                       Any CMake packages not detected by the automatic
#                       dependency extraction logic.
#
function(get_kf5_binding_info)
    cmake_parse_arguments(
        ARG
        ""
        ""
        "COMPONENTS;DEPENDENCIES"
        ${ARGN})
    if(NOT "${ARG_UNPARSED_ARGUMENTS}" STREQUAL "")
        message(SEND_ERROR "Unexpected arguments specified '${ARG_UNPARSED_ARGUMENTS}'")
    endif()
    if("${ARG_COMPONENTS}" STREQUAL "")
        message(SEND_ERROR "No COMPONENTS specified")
    endif()
    #
    # Find dependencies and other info.
    #
    set(_H_DIRS)
    set(_H_FILES)
    set(_COMPILE_OPTIONS)
    set(_INCLUDE_DIRS)
    set(_LINK_LIBRARIES)
    foreach(component IN LISTS ARG_COMPONENTS)
        get_kf5_info(${component})
        #
        # Automatic dependencies.
        #
        list(APPEND _DEPENDENCIES ${dependencies})
        list(REMOVE_DUPLICATES _DEPENDENCIES)
        #
        # Other info.
        #
        get_targets_info(${component} ${targets})
        list(APPEND _H_DIRS ${includes})
        list(APPEND _LINK_LIBRARIES ${libraries})
        list(APPEND _COMPILE_OPTIONS "${compile_flags}")
        list(REMOVE_DUPLICATES _H_DIRS)
        list(REMOVE_DUPLICATES _LINK_LIBRARIES)
        list(REMOVE_DUPLICATES _COMPILE_OPTIONS)
    endforeach(component)
    #
    # Find all header files.
    #
    foreach(h_dir IN LISTS _H_DIRS)
        file(GLOB tmp ${h_dir}/*.h)
        list(APPEND _H_FILES ${tmp})
        list(REMOVE_DUPLICATES _H_FILES)
    endforeach(h_dir)
    list(FILTER _H_FILES EXCLUDE REGEX ".*_version.h")
    #
    # Add dependencies.
    #
    foreach(component IN LISTS _DEPENDENCIES ARG_DEPENDENCIES)
        string(FIND ${component} "KF5" found_kf5)
        string(FIND ${component} "Qt5" found_qt5)
        if(component MATCHES "^KF5")
            get_kf5_info(${component})
        elseif(component MATCHES "^Qt5")
            get_qt5_info(${component})
        endif()
        get_targets_info(${component} "${targets}")
        list(APPEND _INCLUDE_DIRS ${includes})
        list(APPEND _LINK_LIBRARIES ${libraries})
        list(APPEND _COMPILE_OPTIONS "${compile_flags}")
        list(REMOVE_DUPLICATES _INCLUDE_DIRS)
        list(REMOVE_DUPLICATES _LINK_LIBRARIES)
        list(REMOVE_DUPLICATES _COMPILE_OPTIONS)
    endforeach(component)
    #
    # Find the version from the first component.
    #
    list(GET ARG_COMPONENTS 1 first_component)
    include(${${first_component}_DIR}/${first_component}ConfigVersion.cmake)
    #
    # Return results.
    #
    set(version ${PACKAGE_VERSION} PARENT_SCOPE)
    set(h_dirs ${_H_DIRS} PARENT_SCOPE)
    set(h_files ${_H_FILES} PARENT_SCOPE)
    set(include_dirs ${_INCLUDE_DIRS} PARENT_SCOPE)
    set(compile_options ${_COMPILE_OPTIONS} PARENT_SCOPE)
    set(link_libraries ${_LINK_LIBRARIES} PARENT_SCOPE)
    #message("version=${PACKAGE_VERSION}")
    #message("h_dirs=${_H_DIRS}")
    #message("h_files=${_H_FILES}")
    #message("include_dirs=${_INCLUDE_DIRS}")
    #message("compile_options=${_COMPILE_OPTIONS}")
    #message("link_libraries=${_LINK_LIBRARIES}")
endfunction(get_kf5_binding_info)

#
# Main code.
#
get_kf5_binding_info(
    COMPONENTS KF5Akonadi KF5AkonadiCalendar KF5AkonadiContact KF5AkonadiMime KF5AkonadiNotes KF5AkonadiSearch
    DEPENDENCIES KF5Konq)
list(FILTER h_files EXCLUDE REGEX ".*qtest_akonadi.h")
list(FILTER h_files EXCLUDE REGEX ".*/KF5/[^/]+.h")
CPPYY_ADD_BINDINGS(
    "KF5.Akonadi" "${version}" "Shaheed" "[email protected]"
    LANGUAGE_STANDARD "14"
    GENERATE_OPTIONS "-D__PIC__;-Wno-macro-redefined"
    INCLUDE_DIRS ${include_dirs}
    LINK_LIBRARIES ${link_libraries}
    H_DIRS ${h_dirs}
    H_FILES ${h_files})