repo/gentoo:master commit in: dev-python/ipython/

commit:     061630d9f8a1bed1c54455c5400e3c3a2225c077
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  4 05:11:59 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Aug  4 07:44:00 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=061630d9

dev-python/ipython: Bump to 9.16.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ipython/Manifest              |   2 +
 dev-python/ipython/ipython-9.16.1.ebuild | 145 +++++++++++++++++++++++++++++++
 2 files changed, 147 insertions(+)

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 5545d5a70bb8..1937caf66edf 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,3 +2,5 @@ DIST ipython-9.15.0.tar.gz 4442580 BLAKE2B b00d3c5f982cee6520c58b8fa134d210844c6
 DIST ipython-9.15.0.tar.gz.provenance 9767 BLAKE2B 099f94a81f4237125d58fccded24a97f7bd62094b8eb3f4ee6f8fedaf5a9414740fcbb3f6be1d75ab45d5fbefe40159dcccdf03ec32bacbad18f79629c59d738 SHA512 bafe3c12ca0ebd02dbebdb2f14ad49ef49f33075f889fcb899f68bcccb8f4adf6cf7df8e6949562d7ce9632b2a2305ce0d5bbed4d8f428ae479ada2cd60c3711
 DIST ipython-9.16.0.tar.gz 4515375 BLAKE2B 0a050f5a5f15bdb8cc1ef90264a3119d32964b44988290e1760d2b6eae59ca0238ab160024012aab0f85dd673e0ad5017b22dc18cfb64a4c9adb4b358c2e279d SHA512 752b7c4e82360550afb49acda44e4903832abad2faaf166a1106856acad4f1e81623554f951812ebdb950c7ff2343c556e3b2f56bec9e1d214659df1c12a2102
 DIST ipython-9.16.0.tar.gz.provenance 9552 BLAKE2B 1a42375e6f7f2c96a17bb44e7c10a5696dc854ad88182ae40e2eb06004d3887b7d15b07d2f0fa0c5868e827a8bdebea3e9e5974ddcf0a502e62ec64269362579 SHA512 b770718c729c6c23f32c3a30040d601e9452eaed277c4957a4b03e2b35f8be57dfc1f2cd4523bd8917e40e074df2844a9057db9fb1087bb99fda56246a1806d0
+DIST ipython-9.16.1.tar.gz 4515302 BLAKE2B 45412c6eeae21026d701ca75678a2f6b9dbbdad13505a5d5742bf8e2c7c2590d2b59a00b06e56560ebbb5e489f168865675818a4e385df86079432487ce2d1f8 SHA512 3d144661ae6521eaf738e71b18b4c89cfca66ac088c53c1ca01eb9be71981769927d5ea5966c8b165badb7143fd34fc4d7fed41a32859e9d003d2ba17511431b
+DIST ipython-9.16.1.tar.gz.provenance 9689 BLAKE2B 665fb5f17b407b1b6d82459550901892130bc19c6d88ff6d4857702fa6995b2b9d125de448a5501254cb195f5368070438f2d6aaa3ae87312a90d3a4dd06e90b SHA512 ee98b364ff7c94b8b4e2a31e98818fd3646c23a693d1e5221723ddecd66b8fbe8c65b01360e4111f2a765641fc6908a44fb03408b25f3cd643afa4b9507c5e03

diff --git a/dev-python/ipython/ipython-9.16.1.ebuild b/dev-python/ipython/ipython-9.16.1.ebuild
new file mode 100644
index 000000000000..cabcac39e715
--- /dev/null
+++ b/dev-python/ipython/ipython-9.16.1.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYPI_VERIFY_REPO=https://github.com/ipython/ipython
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature toolchain-funcs pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples gui notebook nbconvert +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/ipython-pygments-lexers-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.18.2[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1.6[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.7[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/psutil-7[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14.0[${PYTHON_USEDEP}]
+	>=dev-python/stack-data-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	>=dev-python/setuptools-80[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.9[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-2.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		>=dev-python/packaging-23.0.0[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		>=dev-python/testpath-0.2[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		gui? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+	' 3.{12..14})
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=()
+
+	if [[ $(tc-get-ptr-size) == 4 ]] ; then
+		EPYTEST_DESELECT+=(
+			# https://github.com/ipython/ipython/issues/15107
+			IPython/extensions/ipython_tests/test_deduperreload.py::DecoratorPatchingSuite::test_function_decorator_from_other_module
+			IPython/extensions/ipython_tests/test_deduperreload.py::DecoratorPatchingSuite::test_function_decorators
+			IPython/extensions/tests/test_deduperreload.py::DecoratorPatchingSuite::test_method_decorator
+		)
+	fi
+
+	# nonfatal implied by virtx
+	nonfatal epytest || die "Tests failed on ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy?
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	# TODO2: figure out what TODO meant.
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}