repo/proj/guru:dev commit in: media-sound/Tauon/

commit:     8f540670b635a63b65d01288080b39f98b1c9591
Author:     David Roman <stkw0 <AT> disroot <DOT> org>
AuthorDate: Tue Aug  4 12:37:41 2026 +0000
Commit:     David Roman <stkw0 <AT> disroot <DOT> org>
CommitDate: Tue Aug  4 12:38:13 2026 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=8f540670

media-sound/Tauon: enable tests

Closes: https://bugs.gentoo.org/976816
Signed-off-by: David Roman <stkw0 <AT> disroot.org>

 media-sound/Tauon/Tauon-11.1.1-r1.ebuild | 120 +++++++++++++++++++++++++++++++
 1 file changed, 120 insertions(+)

diff --git a/media-sound/Tauon/Tauon-11.1.1-r1.ebuild b/media-sound/Tauon/Tauon-11.1.1-r1.ebuild
new file mode 100644
index 0000000000..5d8730e250
--- /dev/null
+++ b/media-sound/Tauon/Tauon-11.1.1-r1.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/rapidfuzz[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+EPYTEST_DESELECT=( src/tauon/tests/test_launch.py::test_launch_main_script )
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+python_test() {
+	epytest -vvv src/tauon/tests
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+	optfeature "Discord Rich Presence support" dev-python/pypresence
+
+	xdg_pkg_postinst
+}