repo/gentoo:master commit in: app-mobilephone/gammu/

commit:     49e2322d65123ecfac233049312f3db98ec72b26
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  5 01:42:27 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug  5 01:55:40 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=49e2322d

app-mobilephone/gammu: Bump to 1.44.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 app-mobilephone/gammu/Manifest            |  1 +
 app-mobilephone/gammu/gammu-1.44.0.ebuild | 68 +++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/app-mobilephone/gammu/Manifest b/app-mobilephone/gammu/Manifest
index b083ab159211..601fe7446019 100644
--- a/app-mobilephone/gammu/Manifest
+++ b/app-mobilephone/gammu/Manifest
@@ -1 +1,2 @@
+DIST Gammu-1.44.0.tar.zst 2554077 BLAKE2B 375a1393664c0dc058d2ce1884ad1e08ac6aaef1cd6b03f82c3b270793b06471a8a5c67ff88bd545f7e50a2bcfbbf38bc233a1dbe1110eea16e3cc94bbc3a18b SHA512 52ca627149a8a19f9a4193b43a6ecb12d4705ddad4a1d299335120aa06ef3107e9c0a75756845def1b345f80f15605c13ce5112dd1e4db262fe287b2c55ef67b
 DIST gammu-1.42.0.tar.xz 1747520 BLAKE2B 13f2627ad189e8ca92da2b16c4f7f5f792f601ca5f7620e251526f79b399b54eb3fb46b420ccb81d4bb44c7777d417c96390001d30dbbe9740eb3d737c574716 SHA512 b1826b011b7af15c87bd1e9214536607450553f9b5c7ba9b40ea2a1b9d8dcc8cab61106055fcb4aeb69e78ea29d2f4986ffd7df20210ed76bc6a0c474e140ba1

diff --git a/app-mobilephone/gammu/gammu-1.44.0.ebuild b/app-mobilephone/gammu/gammu-1.44.0.ebuild
new file mode 100644
index 000000000000..96c9c7c3128c
--- /dev/null
+++ b/app-mobilephone/gammu/gammu-1.44.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake unpacker
+
+DESCRIPTION="A tool to handle your cellular phone"
+HOMEPAGE="https://wammu.eu/gammu/"
+SRC_URI="https://github.com/gammu/gammu/releases/download/${PV}/${P^}.tar.zst"
+S=${WORKDIR}/${P^}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bluetooth curl dbi debug irda mysql nls odbc postgres usb"
+
+COMMON_DEPEND="
+	dev-libs/glib:2=
+	dev-libs/libgudev:=
+	virtual/libiconv
+	bluetooth? ( net-wireless/bluez:= )
+	curl? ( net-misc/curl:= )
+	dbi? ( >=dev-db/libdbi-0.8.3:= )
+	mysql? ( dev-db/mysql-connector-c:= )
+	nls? ( sys-devel/gettext )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:= )
+	usb? ( virtual/libusb:1= )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	irda? ( virtual/os-headers )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-util/dialog
+"
+BDEPEND="
+	app-arch/zstd
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_BLUETOOTH=$(usex bluetooth)
+		-DWITH_CURL=$(usex curl)
+		-DWITH_Gettext=$(usex nls)
+		-DWITH_Iconv=$(usex nls)
+		-DWITH_IRDA=$(usex irda)
+		-DWITH_LibDBI=$(usex dbi)
+		-DWITH_MySQL=$(usex mysql)
+		-DWITH_ODBC=$(usex odbc)
+		-DWITH_Postgres=$(usex postgres)
+		-DWITH_USB=$(usex usb)
+		-DINSTALL_DOC_DIR="share/doc/${PF}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	addwrite "/var/lock/LCK..bar"
+	LD_LIBRARY_PATH="${BUILD_DIR}/libgammu" cmake_src_test -j1
+}
+
+src_install() {
+	cmake_src_install
+	docompress -x /usr/share/doc/${PF}/examples/
+}