repo/gentoo:master commit in: mail-mta/courier/

commit:     157dc829a34db6085b6d2b2c8587d83cf86bd8f3
Author:     Hanno Böck <hanno <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  5 08:48:27 2026 +0000
Commit:     Hanno Böck <hanno <AT> gentoo <DOT> org>
CommitDate: Wed Aug  5 08:48:29 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=157dc829

mail-mta/courier: add 2.0.7

Signed-off-by: Hanno Böck <hanno <AT> gentoo.org>

 mail-mta/courier/Manifest             |   1 +
 mail-mta/courier/courier-2.0.7.ebuild | 313 ++++++++++++++++++++++++++++++++++
 2 files changed, 314 insertions(+)

diff --git a/mail-mta/courier/Manifest b/mail-mta/courier/Manifest
index ccb6021140de..85cbc131d4d5 100644
--- a/mail-mta/courier/Manifest
+++ b/mail-mta/courier/Manifest
@@ -6,3 +6,4 @@ DIST courier-2.0.2.tar.bz2 8557149 BLAKE2B 995263db61bbab819140073a9c89baf9700c2
 DIST courier-2.0.3.tar.bz2 8557844 BLAKE2B 9325580d0c1a6cb3c9e26f11197a5547e3cb8e09c5da326bfc20647a8d0279878f88ae5f82f6b41e21250ac29b862c01bb20314759300ba0b660b031ee44b0db SHA512 4b3c5b6c0ff178ecf62e156234d4277229d7386e0438d5458a8b7284079e255cc4f642f52460a7ecb55fdb18b925fadd59f905f44b5ed39640530ccd06657543
 DIST courier-2.0.4.tar.bz2 8557686 BLAKE2B 729a87706c6c4c1ee3a76cbc8293f5426a466f69d07f546834e53dd27e1aecad99982a3ffa482020c9adb9d67231733cfd31767d4fa1f1100a16b1ea7b0be953 SHA512 a94699bc2c79cf101139671dfb2967c53450919fa007a2c329334e7101975c3945181caeb7fe1344c827e30cd7a9ede064483b4a261d19a7cfa5ca2029804c40
 DIST courier-2.0.6.tar.bz2 8556808 BLAKE2B a234e87119ffd4a38ac72a6ad005447555bdf05e528990e32fa7a36778396dd7cbe6b9fcab230507d925bd6631502feec0d36f3b9b19c466dab707fe922df771 SHA512 bda94c1b74b330d8f512ed0a71dc46e427de1510a2086f36cdf656763b5f91e36bea3eff4ecee68f0862b728e53015591237e9daad1cdbd62091b989bed43eae
+DIST courier-2.0.7.tar.bz2 8558429 BLAKE2B ac47c2e50ddb0aaf2e364f96f79d9bdf399d1624107b89df35a2df5402bc32ada2dafd6778a505c52e2a64bf704053495de9371eceef9ec691d290cc0d1975b6 SHA512 4ad1cf64177abd2077a927d12a79b4fc25394fd6d801c00c2020bfa1abc13e153492c64da52d741de7f00cf0a10fd17e6e23f5c3f0ab6efef13a46900193bfe0

diff --git a/mail-mta/courier/courier-2.0.7.ebuild b/mail-mta/courier/courier-2.0.7.ebuild
new file mode 100644
index 000000000000..883674b1a8fd
--- /dev/null
+++ b/mail-mta/courier/courier-2.0.7.ebuild
@@ -0,0 +1,313 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="An MTA designed specifically for maildirs"
+HOMEPAGE="https://www.courier-mta.org/"
+SRC_URI="https://downloads.sourceforge.net/courier/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="postgres ldap mysql pam nls ipv6 spell fax crypt norewrite \
+	fam web webmail gnutls split-usr test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=net-libs/courier-authlib-0.73.2
+	>=net-libs/courier-unicode-2.6.0:=
+	net-dns/libidn2:=
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	>=sys-libs/gdbm-1.8.0:=
+	dev-libs/libpcre2
+	app-misc/mime-types
+	dev-lang/perl:=
+	fax? ( >=media-libs/netpbm-9.12 app-text/ghostscript-gpl >=net-dialup/mgetty-1.1.28 )
+	pam? ( sys-libs/pam )
+	mysql? ( dev-db/mysql-connector-c )
+	ldap? ( >=net-nds/openldap-1.2.11:= )
+	postgres? ( dev-db/postgresql:= )
+	spell? ( app-text/aspell )
+	fam? ( virtual/fam )
+	!mail-filter/maildrop
+	!mail-mta/esmtp
+	!mail-mta/exim
+	!mail-mta/msmtp[mta]
+	!mail-mta/netqmail
+	!mail-mta/nullmailer
+	!mail-mta/postfix
+	!mail-mta/sendmail
+	!mail-mta/ssmtp[mta]
+	!mail-mta/opensmtpd
+	!net-mail/dot-forward
+	!sys-apps/ucspi-tcp
+	test? ( dev-debug/valgrind )
+	"
+
+RDEPEND="${DEPEND}
+	sys-process/procps"
+
+# get rid of old style virtual/imapd - bug 350792
+# all blockers really needed?
+RDEPEND="${RDEPEND}
+	!net-mail/courier-imap
+	!net-mail/cyrus-imapd"
+
+PDEPEND="pam? ( net-mail/mailbase )
+	crypt? ( >=app-crypt/gnupg-1.0.4 )"
+
+src_prepare() {
+	use norewrite && eapply "${FILESDIR}/norewrite.patch"
+	default
+}
+
+src_configure() {
+	filter-flags '-fomit-frame-pointer'
+
+	local myconf
+	myconf=""
+
+	use ldap && myconf="${myconf} --with-ldapconfig=/etc/courier/maildropldap.conf"
+
+	econf ${myconf} \
+		$(use_with fam) \
+		$(use_with ipv6) \
+		$(use_with spell ispell) \
+		$(use_with ldap ldapaliasd) \
+		$(use_enable ldap maildroldap) \
+		$(use_with gnutls) \
+		--with-notice=unicode \
+		--enable-mimetypes=/etc/mime.types \
+		--prefix=/usr \
+		--disable-root-check \
+		--mandir=/usr/share/man \
+		--sysconfdir=/etc/courier \
+		--datadir=/usr/share/courier \
+		--sharedstatedir=/var/lib/courier/com \
+		--localstatedir=/var/lib/courier \
+		--with-piddir=/var/run/courier \
+		--with-authdaemonvar=/var/lib/courier/authdaemon \
+		--with-mailuser=mail \
+		--with-mailgroup=mail \
+		--with-paranoid-smtpext \
+		--with-db=gdbm \
+		--disable-autorenamesent \
+		--cache-file="${S}/configuring.cache" \
+		--host="${CHOST}" debug=true || die "./configure"
+}
+
+src_compile() {
+	default
+}
+
+etc_courier() {
+	# Import existing /etc/courier/file if it exists.
+	# Add option only if it was not already set or even commented out
+	local file="${1}" word=$(echo "${2}" | sed -e "s|=.*$||" -e "s|^.*opt ||")
+	[ ! -e "${D}/etc/courier/${file}" ] && [ -e "/etc/courier/${file}" ] && \
+			cp "/etc/courier/${file}" "${D}/etc/courier/${file}"
+	grep -q "${word}" "${D}/etc/courier/${file}" || \
+		echo "${2}" >> "${D}/etc/courier/${file}"
+}
+
+etc_courier_chg() {
+	local file="${1}" key="${2}" value="${3}" section="${4}"
+	[ -z "${section}" ] && section="${2}"
+	grep -q "${key}" "${file}" && elog "Changing ${file}: ${key} to ${value}"
+	sed -i -e"/\#\#NAME: ${section}/,+30 s|${key}=.*|${key}=\"${value}\"|g" ${file}
+}
+
+src_install() {
+	local f
+	diropts -o mail -g mail
+	keepdir /var/lib/courier/tmp
+	keepdir /var/lib/courier/msgs
+	make install DESTDIR="${D}" || die "install"
+	make install-configure DESTDIR="${D}" || die "install-configure"
+
+	# init script takes care of this
+	rm -rf "${D}/var/run"
+
+	# Get rid of files we dont want
+	if ! use webmail ; then
+		rm -rf "${D}/usr/$(get_libdir)/courier/courier/webmail" \
+			"${D}/usr/$(get_libdir)/courier/courier/sqwebmaild" \
+			"${D}/usr/share/courier/sqwebmail/" \
+			"${D}/usr/sbin/webmaild" \
+			"${D}/usr/sbin/webgpg" \
+			"${D}/etc/courier/webmail.authpam" \
+			"${D}/var/lib/courier/webmail-logincache" \
+			"${D}"/etc/courier/sqwebmaild*
+	fi
+
+	if ! use web ; then
+		rm -rf "${D}/usr/share/courier/courierwebadmin/" \
+			"${D}/etc/courier/webadmin"
+	fi
+
+	for dir2keep in $(cd "${D}" && find ./var/lib/courier -type d) ; do
+		keepdir "$dir2keep" || die "failed running keepdir: $dir2keep"
+	done
+
+	newinitd "${FILESDIR}/courier-init-r4" "courier"
+	use fam || sed -i -e's|^.*use famd$||g' "${D}/etc/init.d/courier"
+
+	cd "${D}/etc/courier"
+	if use webmail ; then
+		insinto /etc/courier
+		newins "${FILESDIR}/apache-sqwebmail.inc" apache-sqwebmail.inc
+	fi
+
+	for f in *.dist ; do cp "${f}" "${f%%.dist}" ; done
+	if use ldap ; then
+		[ -e ldapaliasrc ] &&  ( chown root:mail ldapaliasrc ; chmod 640 ldapaliasrc )
+	else
+		rm -f ldapaliasrc
+	fi
+
+	( [ -e /etc/courier/sizelimit ] && cat /etc/courier/sizelimit || echo 0 ) \
+		> "${D}/etc/courier/sizelimit"
+	etc_courier maildroprc ""
+	etc_courier esmtproutes ""
+	etc_courier backuprelay ""
+	etc_courier locallowercase ""
+	etc_courier bofh "opt BOFHBADMIME=accept"
+	etc_courier bofh "opt BOFHSPFTRUSTME=1"
+	etc_courier bofh "opt BOFHSPFHELO=pass,neutral,unknown,none,error,softfail,fail"
+	etc_courier bofh "opt BOFHSPFHELO=pass,neutral,unknown,none"
+	etc_courier bofh "opt BOFHSPFFROM=all"
+	etc_courier bofh "opt BOFHSPFMAILFROM=all"
+	etc_courier bofh "#opt BOFHSPFHARDERROR=fail"
+	etc_courier esmtpd "BOFHBADMIME=accept"
+	etc_courier esmtpd-ssl "BOFHBADMIME=accept"
+	etc_courier esmtpd-msa "BOFHBADMIME=accept"
+
+	use fam && etc_courier_chg imapd IMAP_CAPABILITY "IMAP4rev1 UIDPLUS CHILDREN NAMESPACE THREAD=ORDEREDSUBJECT THREAD=REFERENCES SORT QUOTA AUTH=CRAM-MD5 AUTH=CRAM-SHA1 AUTH=CRAM-SHA256 IDLE"
+	use fam || etc_courier_chg imapd IMAP_CAPABILITY "IMAP4rev1 UIDPLUS CHILDREN NAMESPACE THREAD=ORDEREDSUBJECT THREAD=REFERENCES SORT QUOTA AUTH=CRAM-MD5 AUTH=CRAM-SHA1 AUTH=CRAM-SHA256"
+
+	# Fix for a sandbox violation on subsequential merges
+	# - [email protected], 2005-07-10
+	dosym ../share/courier/pop3d /usr/sbin/courier-pop3d
+	dosym ../share/courier/pop3d-ssl /usr/sbin/courier-pop3d-ssl
+	dosym ../share/courier/imapd /usr/sbin/courier-imapd
+	dosym ../share/courier/imapd-ssl /usr/sbin/courier-imapd-ssl
+
+	cd "${S}"
+	cp imap/README README.imap
+	use nls && cp unicode/README README.unicode
+	dodoc AUTHORS BENCHMARKS COPYING* ChangeLog* INSTALL NEWS README* TODO courier/doc/*.txt
+	dodoc libs/tcpd/README.couriertls
+	mv "${D}/usr/share/courier/htmldoc" "${D}/usr/share/doc/${PF}/html"
+
+	if use webmail ; then
+		insinto /usr/$(get_libdir)/courier/courier
+		insopts -m 755 -o mail -g mail
+		doins "${S}/courier/webmaild"
+	fi
+
+	if use web ; then
+		insinto /etc/courier/webadmin
+		insopts -m 400 -o mail -g mail
+		doins "${FILESDIR}/password.dist"
+	fi
+
+	# avoid name collisions in /usr/sbin, make webadmin match
+	cd "${D}/usr/sbin"
+	for f in imapd imapd-ssl pop3d pop3d-ssl ; do mv "${f}" "courier-${f}" ; done
+	if use web ; then
+		sed -i -e 's:\$sbindir\/imapd:\$sbindir\/courier-imapd:g' \
+			-e 's:\$sbindir\/imapd-ssl:\$sbindir\/courier-imapd-ssl:g' \
+			"${D}/usr/share/courier/courierwebadmin/admin-40imap.pl" \
+			|| ewarn "failed to fix webadmin"
+		sed -i -e 's:\$sbindir\/pop3d:\$sbindir\/courier-pop3d:g' \
+			-e 's:\$sbindir\/pop3d-ssl:\$sbindir\/courier-pop3d-ssl:g' \
+			"${D}/usr/share/courier/courierwebadmin/admin-45pop3.pl" \
+			|| ewarn "failed to fix webadmin"
+	fi
+
+	# users should be able to send mail. Could be restricted with suictl.
+	chmod u+s "${D}/usr/bin/sendmail"
+
+	if use split-usr; then
+		dosym ../bin/sendmail /usr/sbin/sendmail
+	fi
+}
+
+src_test() {
+	if [ `whoami` = 'root' ]; then
+		einfo "make check skipped, can't run as root."
+		einfo "You can enable it with FEATURES=\"userpriv\""
+	elif [ $(locale -a|grep '^en_US.iso88591$\|^en_US.utf8$'|wc -l) -le 2 ]; then
+		einfo "make check skipped, tests need en_US.iso88591 and en_US.utf8 locales."
+	else
+		emake -j1 check
+	fi
+}
+
+pkg_postinst() {
+	use fam && elog "fam daemon is needed for courier-imapd" \
+		|| ewarn "courier was built without fam support"
+}
+
+pkg_config() {
+	mailhost="$(hostname)"
+	export mailhost
+
+	domainname="$(domainname)"
+	if [ "x$domainname" = "x(none)" ] ; then
+		domainname="$(echo ${mailhost} | sed -e "s/[^\.]*\.\(.*\)/\1/")"
+	fi
+	export domainname
+
+	if [[ -z "${ROOT}" ]] ; then
+		file="${ROOT}/etc/courier/locals"
+		if [ ! -f "${file}" ] ; then
+			echo "localhost" > "${file}";
+			echo "${domainname}" >> "${file}";
+		fi
+		file="${ROOT}/etc/courier/esmtpacceptmailfor.dir/${domainname}"
+		if [ ! -f "${file}" ] ; then
+			echo "${domainname}" > "${file}"
+			/usr/sbin/makeacceptmailfor
+		fi
+
+		file="${ROOT}/etc/courier/smtpaccess/${domainname}"
+		if [ ! -f "${file}" ]
+		then
+			netstat -nr | grep "^[1-9]" | while read network gateway netmask rest
+			do
+				i=1
+				net=""
+				TIFS="${IFS}"
+				IFS="."
+				for o in "${netmask}"
+				do
+					if [ "${o}" == "255" ]
+					then
+						[ "_${net}" == "_" ] || net="${net}."
+						t="$(echo "${network}" | cut -d " " -f ${i})"
+						net="${net}${t}"
+					fi
+					i="$((${i} + 1))"
+				done
+				IFS="${TIFS}"
+				echo "doing configuration - relay control for the network ${net} !"
+				echo "${net}	allow,RELAYCLIENT" >> ${file}
+			done
+			/usr/sbin/makesmtpaccess
+		fi
+	fi
+
+	echo "creating cert for esmtpd-ssl:"
+	/usr/sbin/mkesmtpdcert
+	echo "creating cert for imapd-ssl:"
+	/usr/sbin/mkpop3dcert
+	echo "creating cert for pop3d-ssl:"
+	/usr/sbin/mkimapdcert
+}