repo/gentoo:master commit in: dev-python/django/

commit:     e08b4d5c076843dd7ed47ea03fe60bf709ec7690
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  6 03:56:20 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug  6 03:56:20 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e08b4d5c

dev-python/django: Bump to 6.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest          |   2 +
 dev-python/django/django-6.1.ebuild | 100 ++++++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 70673c47c537..970c946f2ac0 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,4 +1,6 @@
 DIST Django-5.2.17.checksum.txt 2609 BLAKE2B 02c9c13623a5dbed385b41323f8b65173933df368a05d1a1e70fcc1f58a34a983a3c4d001907e35b5b759e1493f3afa157be675077adf7dbb2fbb84a9c26a88c SHA512 b5c5d7b8645669e074ac1a76d3ad307cf1e3d66bbc08ad33abf3107bc1e7b8d43424d2a6cdd6f244994ce33554fd408a292ce6eac03d577d247f4276bdf5f415
 DIST Django-6.0.8.checksum.txt 2598 BLAKE2B e5f3ed079b63754f159c753dc8e74cfc539beade44ec790a318e029ff8a149b0abe90ac31a4bd4dddd7bc563c1a2460ecd51d7deb03520a2f6cc28a41663923d SHA512 f75c78d6506be1d31cf984e029d0bc4e80fa415ac5a83c0e57b5ecc873240da8af4962cb1b262efc032a274a017e265cb8806d397c1720bab247f3592a2eaf8d
+DIST Django-6.1.checksum.txt 2584 BLAKE2B b29f77a03a8d25cbcc5110e521da361198456da4e3a5278500d1fdc0f20d6e1edf4ca326fa5c5aa8e01f6cf6ca8deac2954807e067cd9fef7cc799fad8c95b2a SHA512 3f7f21a872b01aa567eccea135f2245ce3cd091f6b6752ac4ff63d285b5f0b3b6c3c86cd7fb6c4c6000081257313c70bc4e9ad016444f93cd826416cf053071a
 DIST django-5.2.17.tar.gz 10889740 BLAKE2B 2cb1bcb7f2f872dd3c01447709a2f35c74ecd9470ce332b616bdf04e5951d38405380af19001ace033351330f7f645ed61c9b628cea21665f92c3757fcda5e0c SHA512 3f960e8227ab71d42f33700e689db6f359411d43efd3b138c59e66aac245a110f33458dcc9e7b27ddbda16b2a1c97e1e56ce00c9ace8294216eded8a4af8815f
 DIST django-6.0.8.tar.gz 10924565 BLAKE2B 9a0e4ff8f0548874080cc59982d64881892bb8c71c4edf346dff68628e6c98366e66a7e4f6e0a39edab0fb7b513e36fd2e3dc41f94743c72dae8113e4fda1780 SHA512 ae763252794b15a0cfd47bcf2eab00cb12bceeebdf7abc7c295ed41cb0b1b60ffbe2c2abbd032de9afaa193d63aa89c5d8df9ce3f58164a2dcb8c70ba6244764
+DIST django-6.1.tar.gz 11223034 BLAKE2B 32fd3fbd7f496d18fda84b992fd9aafdca3a1a3526342ded90bea2df78577b434b6122a8213372e02b0477a9718f5577f772b9052fc3e0b8caade0814ffd058a SHA512 5fa4d78b67790d07560fa19269006b08f5ea3053bd0f3df2a1e54589ad19d46cdcbb5c14d7e4d339ec1106419b3cbbfe3e05c7c563958668498dfe421c6f4ca7

diff --git a/dev-python/django/django-6.1.ebuild b/dev-python/django/django-6.1.ebuild
new file mode 100644
index 000000000000..bf6a2346455c
--- /dev/null
+++ b/dev-python/django/django-6.1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit distutils-r1 multiprocessing optfeature shell-completion verify-sig
+
+MY_P=${P/_}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P^}.checksum.txt )
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.9.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.5.0[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		>=dev-python/docutils-0.19[${PYTHON_USEDEP}]
+		>=dev-python/jinja2-2.11.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/selenium-4.8.0[${PYTHON_USEDEP}]
+		>=dev-python/tblib-1.5.0[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P^}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+		-v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion django-admin
+	bashcomp_alias django-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:0
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}