repo/gentoo:master commit in: dev-python/awscrt/

commit:     45dbb998c98f3a2bcc48fc959cf89ec3d217e153
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  6 14:02:13 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug  6 14:04:38 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45dbb998

dev-python/awscrt: New package, v0.36.1

Optional dependency of <dev-python/awscrt-2, apparently required for 2+.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/awscrt/Manifest             |  1 +
 dev-python/awscrt/awscrt-0.36.1.ebuild | 63 ++++++++++++++++++++++++++++++++++
 dev-python/awscrt/metadata.xml         | 11 ++++++
 3 files changed, 75 insertions(+)

diff --git a/dev-python/awscrt/Manifest b/dev-python/awscrt/Manifest
new file mode 100644
index 000000000000..2c397a08a93f
--- /dev/null
+++ b/dev-python/awscrt/Manifest
@@ -0,0 +1 @@
+DIST awscrt-0.36.1.tar.gz 37073487 BLAKE2B e2807fe2a0c0389c420c610fbbbdb9f1e43d130a85a8c20e85f4abcf0dd42200a9a8779b1ff4970378200cabee8822f7cfd158964142633dd2b5728dbe6404cb SHA512 bc0663307af5694318dd3b7733598aa7826cec9ed5904bd798a32c6aa0544112516634ab1c8f7f3558547fcd7f38ee0c1cb5348b1b0726e242f9852562b7e5c3

diff --git a/dev-python/awscrt/awscrt-0.36.1.ebuild b/dev-python/awscrt/awscrt-0.36.1.ebuild
new file mode 100644
index 000000000000..440c096fb447
--- /dev/null
+++ b/dev-python/awscrt/awscrt-0.36.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A common runtime for AWS Python projects"
+HOMEPAGE="
+	https://github.com/awslabs/aws-crt-python/
+	https://pypi.org/project/awscrt/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-libs/aws-c-common:=
+	dev-libs/aws-c-auth:=
+	dev-libs/aws-c-sdkutils:=
+	dev-libs/aws-c-cal:=
+	dev-libs/aws-c-io:=
+	dev-libs/aws-c-compression:=
+	dev-libs/aws-c-event-stream:=
+	dev-libs/aws-c-http:=
+	dev-libs/aws-c-auth:=
+	dev-libs/aws-c-mqtt:=
+	dev-libs/aws-c-s3:=
+	dev-libs/aws-checksums:=
+	dev-libs/openssl:=
+	dev-libs/s2n-tls:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-python/pytest
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# remove bundled libs
+	rm -r crt || die
+	export AWS_CRT_BUILD_USE_SYSTEM_LIBS=1
+
+	# Internet/DNS
+	sed -e 's:test_h2_remote_end_stream_ordering:_&:' \
+		-e 's:test_cross_thread_http2_client:_&:' \
+		-e 's:test_h2_client:_&:' \
+		-e 's:test_h2_manual_write_exception:_&:' \
+		-e 's:test_h2_remote_end_stream_ordering:_&:' \
+		-i test/test_{aio,}http_client.py || die
+}

diff --git a/dev-python/awscrt/metadata.xml b/dev-python/awscrt/metadata.xml
new file mode 100644
index 000000000000..7b5cce3e00ca
--- /dev/null
+++ b/dev-python/awscrt/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>[email protected]</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">awslabs/aws-crt-python</remote-id>
+		<remote-id type="pypi">awscrt</remote-id>
+	</upstream>
+</pkgmetadata>