repo/gentoo:master commit in: media-video/qmplay2/

commit:     8636bb3956f00946247ae8ef391344a2609e78fd
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  6 14:01:54 2026 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Aug  6 14:07:30 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8636bb39

media-video/qmplay2: add 26.08.02

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-video/qmplay2/Manifest                |   1 +
 media-video/qmplay2/qmplay2-26.08.02.ebuild | 129 ++++++++++++++++++++++++++++
 2 files changed, 130 insertions(+)

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 6328e3abbc75..10f5ee8e72c3 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,2 +1,3 @@
 DIST QMPlay2-src-25.09.11.tar.xz 2200356 BLAKE2B be8b54b91011ab6ac5e82cdf7f48119b2d91fbee227737772992958115cbf57da995f8b1018af5d54c05a516fb3dd3a254ddae9ebc70780a7f9549ba19e7f4a8 SHA512 ac53b60259832c2fc168be3ac19d734a6f9bfe5969a399163b8624084f4a545ece6405a34803fa14c0bfc157259247edf3854153e0db5f18e68455a0e3140486
 DIST QMPlay2-src-26.06.27.tar.xz 2313016 BLAKE2B 234a386fe36eb86de5daaf5b9747a2abe4ecfa4e27586656c449ba05090bd9943d941ba32700e15a5486e748eae81bcb5689c4b5ddec3f5f82d8fc0f32ebb5c9 SHA512 3fc051d6cd5b7bbf1df0a3d470b51a9df28765b6a169f54e1cc2b5956eb33b2f9739b46e9cfd65d4550e55e43f6b89db5064648ca1496ea0689568806c068000
+DIST QMPlay2-src-26.08.02.tar.xz 2314916 BLAKE2B 03c77c42abe11ef3cca2b49ae4229ca4d68958b0f458fb391d71ce386e4d00320bd7005936a4f8d2b61075189b9973543773ead167adb96638c36a4fa2961096 SHA512 41c42d8041d600e59a32d2c1988a7d5923d7b5f77b9ccca6c89fd9eeb2a9d720b8e83deabe917a7a7cb70eca84ba5d65f20ccaf9c2830656839d3631832f3eff

diff --git a/media-video/qmplay2/qmplay2-26.08.02.ebuild b/media-video/qmplay2/qmplay2-26.08.02.ebuild
new file mode 100644
index 000000000000..74829ac47566
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-26.08.02.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	libopenmpt notifications opengl pipewire portaudio pulseaudio sid
+	+taglib vaapi videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+"
+
+RDEPEND="
+	dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+	dev-qt/qt5compat:6
+	dev-qt/qtsvg:6
+	media-video/ffmpeg:=[vaapi?]
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	extensions? ( dev-qt/qtdeclarative:6 )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	libopenmpt? ( media-libs/libopenmpt )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( >=media-libs/libsidplayfp-3.0.0 )
+	taglib? ( media-libs/taglib:= )
+	vaapi? ( media-libs/libva[X] )
+	vulkan? (
+		>=media-libs/vulkan-loader-1.2.133
+		>=media-libs/shaderc-2020.1
+	)
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-25.06.27-revert-lld-stuff.patch"
+)
+
+src_prepare() {
+	# disable compress man pages
+	sed -i src/gui/CMakeLists.txt -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=ON
+		# core
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_PM=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_OPENMPT=$(usex libopenmpt)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}