repo/gentoo:master commit in: dev-python/pypdf/

commit:     9e2c2fdeeb0d07b1a0ec0fcc304d18dafd2d28ce
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  7 02:04:02 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug  7 02:29:00 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e2c2fde

dev-python/pypdf: Bump to 6.15.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pypdf/Manifest            |  1 +
 dev-python/pypdf/pypdf-6.15.0.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pypdf/Manifest b/dev-python/pypdf/Manifest
index ec374df252ab..fa299fef8cd4 100644
--- a/dev-python/pypdf/Manifest
+++ b/dev-python/pypdf/Manifest
@@ -1,2 +1,3 @@
 DIST pypdf-6.14.2.gh.tar.gz 9585097 BLAKE2B d24eeea1aeb0d491880d99922c9ab27b6468df6782bc3dc25c1209c3d14b98ef25c8bd72a103f7fb645606f5263fa17280e66a6c0ea72ea56d436f5a65d883bf SHA512 798df3e54a3185a790efbd15f8fc0a0eaff06e6695a4b9529da2108df0391f400f2da483b8cb5cb0c7bc9b131fb54dcc787095787203178853a0fa2573a0428a
+DIST pypdf-6.15.0.gh.tar.gz 10091649 BLAKE2B bc4384287edc9332971ba2c8b80f196ddd1dbc5f03eb8ca8f501fdc4fcbf224a745a536ce368bf3a02cb281a89564b3afeb059414353e60ca1b7da1f15063e8f SHA512 ea4138958ad75707cc536e670420d6cf4c57c4b10f85a46bee763d7b045254aa39d75a4f22303fcc8e104e97581316013f85a084e7baf4ab647e3268792f9dfe
 DIST pypdf-sample-files-818dc013ad1f537198e9fcfae8a6b0dffe25ffa3.gh.tar.gz 11850954 BLAKE2B fbd0af91de44f2d224b3266727f0dfc462efb4d23176f4ebff147cbfa37337d891859c468b545d0c00796048584e6b621dc622d667e3d45c0b89b92f29ca3030 SHA512 bc601bfaf17f31c6358f594eaf879479e97028d7f5e5825c309a5d1eb843bfea5080c9e151287a0d915ecbc3f4d4755e326ac8fa1ceeb696c76b9f5ecc0d7e9f

diff --git a/dev-python/pypdf/pypdf-6.15.0.ebuild b/dev-python/pypdf/pypdf-6.15.0.ebuild
new file mode 100644
index 000000000000..f4cea56570ed
--- /dev/null
+++ b/dev-python/pypdf/pypdf-6.15.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=818dc013ad1f537198e9fcfae8a6b0dffe25ffa3
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-3.1[${PYTHON_USEDEP}]
+		dev-python/fonttools[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,zlib,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		media-libs/jbig2dec[png]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-timeout )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# probably requires extra deps
+	tests/test_appearance_stream.py::test_appearance_stream_rtl
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	epytest -o addopts= -m "not enable_socket"
+}