repo/gentoo:master commit in: sys-kernel/gentoo-kernel-modprep/

commit:     eb6de6f53c7cf9337bd8664175269feb53547533
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  7 17:52:26 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug  7 17:53:48 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb6de6f5

sys-kernel/gentoo-kernel-modprep: Bump to 6.1.182

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-kernel/gentoo-kernel-modprep/Manifest          |   2 +
 .../gentoo-kernel-modprep-6.1.182.ebuild           | 177 +++++++++++++++++++++
 2 files changed, 179 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-modprep/Manifest b/sys-kernel/gentoo-kernel-modprep/Manifest
index 4ddbe0766b9c..b4006bfc7987 100644
--- a/sys-kernel/gentoo-kernel-modprep/Manifest
+++ b/sys-kernel/gentoo-kernel-modprep/Manifest
@@ -1,4 +1,5 @@
 DIST gentoo-kernel-modprep-6.1.180.tar.xz 7426668 BLAKE2B 9533e3dc2646e157b543bb0a4f5476de9fa5b63cc3aeab964535558fa6539032309c498361519201dced74b28efb62f62d832fff05b56b18bf4ccb4563c8801d SHA512 b4dc273b05b66dc80dc7e357ddc8066d8979e2d5402ae3b2a069e11f603f348349d1d95d3eb59eb3f87086c320013db4cb7d5eb8324c02720b53b85a8bf6c530
+DIST gentoo-kernel-modprep-6.1.182.tar.xz 7436788 BLAKE2B f140af48000d872858936fd035ce05d28e6fccdf9be38053e223be1a012c2f4a0085cc802a93b53aa67b7a1913125b9046f038ccb8327872119a28ab5282ca11 SHA512 5af7d311ed80710c9bb60fd98192c998409d38916e8b17f492930cf99fef9f674891cdfe6e24c0b171a19de3da766a4bbcb34c54449ac1ad52b5431a52b407d5
 DIST gentoo-kernel-modprep-6.12.100.tar.xz 8915760 BLAKE2B ad20659b03a2af87db240714a13ff2dc2c24a91191caee0ca49567506b0d132e121f02565e47600ffeffde33897e08dcc12392903083d1ffd6ecc151db885d16 SHA512 e11d2d9b16d5aacf3d23946980bccad595b01e367c626db837ddeb411fe8ef1855bf822976bc505baa5d2a890293f2a0a8eb51035d2cdce61eb00d02c3b5d2b5
 DIST gentoo-kernel-modprep-6.12.101.tar.xz 8902796 BLAKE2B ac483ad419a72b032430ddd758b3ef294e5150f0ab31f7de932ee57a281141c1048f6181d119519fcb909136d11828a5982256d66e795371062eb8d5ca8993c4 SHA512 d6829aec189e49d31ae4a79843b17abbdf2622a3d2878b4127ec4494e744c59638864179bdfecc2147b9bff876fed71dd53f9239bc081599a5dacc1c9b246ca2
 DIST gentoo-kernel-modprep-6.12.102.tar.xz 8901300 BLAKE2B 8eb356b41ff262d9c950801cc2298d1695775c568e867b895a2adfdd86c81e829977b7ba8f2d797cdf577ed506b64012990e19f7888f13b2905a921f78583302 SHA512 63d3af4ce04544bdd718ab99ce09fa48c1ce7e86498e8bd73d8477890edbfc1587c2acdd9fee9b424e33f3d7a04cf4326a39a631e7350f94d3a8b9f2b01ef793
@@ -31,6 +32,7 @@ DIST linux-gentoo-patches-6.6.145.tar.xz 39848 BLAKE2B 46a5473d9d056b691af2bcda3
 DIST linux-gentoo-patches-7.1.5.tar.xz 10484 BLAKE2B 9b65135d72792375660312e27170cf92858c1a5063c38faed02b378dae399d8f119ca3ff1400175c7354d3e14d1b179a96b4087141d6da649b7ce90b3be1af02 SHA512 c496dd761ee462fbad26186c21f5809e6f7c915de17c4dfc9d1b7ff612f9edc45891b7e7b0381d4faaa50091c4699989a89e1162f897bd6f352170157718f94a
 DIST linux-gentoo-patches-7.1.6.tar.xz 9584 BLAKE2B c87be59dce825d5bd5fccb260eb17726e955579e9c8d66609fd2cc2163a5f6ef76cefad2242f5cb278e2657890cc2efc003700cc8fb7ce3bf12fb595641286d5 SHA512 1519faf4e7d7bb9e65ed1f923e59fc20129fabdbc5e95d28273a91ff241d494d5a0cd61ead5a5a174a5188c40b1db7d866f072724f4bd6ac94baf52a3ac325fc
 DIST patch-6.1.180.xz 7846572 BLAKE2B 8cf59bea6c376c6e544b8afe42fcdb19bd00da7b5b984d0d0ffbcf6f44c2d6d320eac5a9ffb3cbdedc5ab6ba840c7e779b1f8676ed292737eb6543793b049b10 SHA512 04ac7f1330e4d9dcf3f8f2bb3b8678ee345dfbfa47e66ac4ba842ff80cb834b6bb49dc513a88726855f4f35eb9150d0c899a0b2e7df5503183efa7718a2b2acd
+DIST patch-6.1.182.xz 7847720 BLAKE2B ccd624399b163cd73233a8655a6613702e6937bfeb2caccdb771f23a1475abf53b483cf30b077fce582addfb53b7727cd3616acbf1a59c4eb6421f1df617965d SHA512 20af466763207f5c107d83b1433c9393142f258c8bc27196e81634b0b30708b484431fd64db2b77f8bd9f2cc3e3e57d81c79362fa020b7ff8d38e36cb045e492
 DIST patch-6.12.100.xz 5245604 BLAKE2B c0fb332fb1bb5ed18cd6dfebe40569b975073ed2b2c7101c04bb8c6281a1a0dea999bc6985adc50860233e4c2ca57c394090625bb83a288122a0c3fdc8142ba0 SHA512 09a74ff66e3bdaa9684ef98c0a4e30979bebe319f119b14b87a62bae2f52d995abba4194ce11ea5e02928d140707fdd7e8e2336a376a0507a5aea1c91a55dba4
 DIST patch-6.12.101.xz 5441064 BLAKE2B 43c53214ad4455f2ef5fa618050f112a24c7e2d00004a76eec63a651f36f4e3c74e4c89f2188a61bef94735c45cde1ea82d2994a8825f065a82349e03e3178dc SHA512 e87b9b56afaa9d42703204d133094e5017f766e5d32961b2e2fe829fc845fca47619faa039653fbd3c43a1d3e7a68e1c9a9e7ad1882fc1e5885496cb66a78534
 DIST patch-6.12.102.xz 5442364 BLAKE2B f28187ded04d35aa19bcc8ca08805cb709e6b5e57781b984fbd6f34e64308ccb7457a9a7e2052e6d371d021a5143fda79a89c41c1954ed7560fb6552d9401c55 SHA512 f23cc10a2a722bd17231322060f711dea1b29c394f2e7e0efa825aebcc84a972e8e724b2be0cca2a3b47f5e20f20a5899cc322faf71b8948f53343ca372c3fe8

diff --git a/sys-kernel/gentoo-kernel-modprep/gentoo-kernel-modprep-6.1.182.ebuild b/sys-kernel/gentoo-kernel-modprep/gentoo-kernel-modprep-6.1.182.ebuild
new file mode 100644
index 000000000000..427456180f87
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-modprep/gentoo-kernel-modprep-6.1.182.ebuild
@@ -0,0 +1,177 @@
+# Copyright 2020-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dist-kernel-utils toolchain-funcs verify-sig
+
+BASE_P=linux-${PV%.*}
+PATCH_PV=${PV%_p*}
+PATCHSET=linux-gentoo-patches-6.1.178
+SHA256SUM_DATE=20260807
+
+DESCRIPTION="Minimal subset of gentoo-kernel-bin for building modules, for containers"
+HOMEPAGE="
+	https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
+	https://www.kernel.org/
+"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${BASE_P}.tar.xz
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/patch-${PATCH_PV}.xz
+	https://distfiles.gentoo.org/pub/proj/dist-kernel/patchsets/$(ver_cut 1-2)/${PATCHSET}.tar.xz
+	https://distfiles.gentoo.org/pub/proj/dist-kernel/binpkg/modprep/$(ver_cut 1-2)/${P}.tar.xz
+	verify-sig? (
+		https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/sha256sums.asc
+			-> linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+SLOT=${PV}
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	virtual/libelf
+	!sys-kernel/gentoo-kernel-bin:${SLOT}
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+BDEPEND="
+	app-alternatives/bc
+	app-alternatives/lex
+	app-alternatives/yacc
+	dev-util/pahole
+	virtual/libelf
+	verify-sig? ( >=sec-keys/openpgp-keys-kernel-20250702 )
+"
+
+KV_LOCALVERSION='-gentoo-dist-bin'
+KV_FULL=${PV/_p/-p}${KV_LOCALVERSION}
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kernel.org.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc" \
+			sha256 "${BASE_P}.tar.xz patch-${PATCH_PV}.xz"
+		cd "${WORKDIR}" || die
+	fi
+
+	unpack "${BASE_P}.tar.xz" "patch-${PATCH_PV}.xz" "${PATCHSET}.tar.xz"
+	local pkg_arch=${ARCH}
+	[[ ${ARCH} == ppc64 ]] && pkg_arch=ppc64le
+	tar -x -f "${DISTDIR}/${P}.tar.xz" "${P}/${pkg_arch}" || die
+}
+
+src_prepare() {
+	local patch
+	cd "${BASE_P}" || die
+	eapply "${WORKDIR}/patch-${PATCH_PV}"
+	eapply "${WORKDIR}/${PATCHSET}"
+
+	default
+
+	# add Gentoo patchset version
+	local extraversion=${PV#${PATCH_PV}}
+	sed -i -e "s:^\(EXTRAVERSION =\).*:\1 ${extraversion/_/-}:" Makefile || die
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local HOSTLD="$(tc-getBUILD_LD)"
+	if type -P "${HOSTLD}.bfd" &>/dev/null; then
+		HOSTLD+=.bfd
+	fi
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+	tc-export_build_env
+	local makeargs=(
+		V=1
+		WERROR=0
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTLD="${HOSTLD}"
+		HOSTAR="$(tc-getBUILD_AR)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP="$(tc-getSTRIP)"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+		READELF="$(tc-getREADELF)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH="$(tc-arch-kernel)"
+
+		O="${WORKDIR}"/modprep
+	)
+
+	local kernel_dir=( "${P}"/*/usr/src/"linux-${KV_FULL}" )
+
+	mkdir modprep || die
+	cp "${kernel_dir}/.config" modprep/ || die
+	emake -C "${BASE_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_install() {
+	local rel_kernel_dir=/usr/src/linux-${KV_FULL}
+	local pkg_dir=( "${P}"/* )
+	local kernel_dir="${pkg_dir}/usr/src/linux-${KV_FULL}"
+	local image="${kernel_dir}/$(dist-kernel_get_image_path)"
+	local uki="${image%/*}/uki.efi"
+
+	mv "${pkg_dir}"/lib "${ED}"/ || die
+	cd "${kernel_dir}" || die
+	insinto "${rel_kernel_dir}"
+	doins System.map Module.symvers
+	doins -r certs include scripts
+
+	local kern_arch=$(tc-arch-kernel)
+	insinto "${rel_kernel_dir}/arch/${kern_arch}"
+	doins -r "arch/${kern_arch}/include"
+
+	# Add the identifier
+	echo "${CATEGORY}/${PF}:${SLOT}" > "${ED}${rel_kernel_dir}/dist-kernel" || die
+
+	cd "${WORKDIR}/${BASE_P}" || die
+	insinto "${rel_kernel_dir}"
+	doins -r include
+
+	# remove everything but Makefile* and Kconfig*
+	find -type f '!' '(' -name 'Makefile*' -o -name 'Kconfig*' ')' \
+		-delete || die
+	find -type l -delete || die
+	cp -p -R * "${ED}${rel_kernel_dir}/" || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	cd "${WORKDIR}" || die
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}${rel_kernel_dir}"/ || die
+}
+
+pkg_preinst() {
+	dist-kernel_update_lib_symlinks
+}
+
+pkg_postinst() {
+	dist-kernel_update_src_symlink "${EROOT}/usr/src/linux" "${KV_FULL}"
+}