repo/gentoo:master commit in: sys-apps/polychromatic/

commit:     d915f89dde52272cc2499e25e55ee0e97053dc79
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  9 11:54:38 2026 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sun Aug  9 13:31:43 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d915f89d

sys-apps/polychromatic: bump to 0.9.8

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 sys-apps/polychromatic/Manifest                   |  1 +
 sys-apps/polychromatic/polychromatic-0.9.8.ebuild | 74 +++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/sys-apps/polychromatic/Manifest b/sys-apps/polychromatic/Manifest
index f4ae27ddb167..f992aba2809b 100644
--- a/sys-apps/polychromatic/Manifest
+++ b/sys-apps/polychromatic/Manifest
@@ -1 +1,2 @@
 DIST polychromatic-0.9.7.gh.tar.gz 1841971 BLAKE2B af565d5d59da289e27a6a25c6ea7ac001ccaa576cc9bf5c623f93cb99ea75438825196a86c6719d8ec39d32f86a6903dfd022d6858cb5dda522fb19b3aaf6696 SHA512 3adf2f0728185b4ce543c821ba1b51870e7fbe7a1b2e1b2969162acb2f60e2d6961b6870984257db067b2f2ed9727ebdda391452737954a123d4bd79c6ca7972
+DIST polychromatic-0.9.8.gh.tar.gz 1910826 BLAKE2B 1a321ffaa4d6a77de3942175d29d6c675d295184dc8f840ce85d62d17ceda2a6b1fb319bf577d729d7722f7b1da3d88e448f6149faa7a5675395f3edf0a9d5e3 SHA512 ad7a47c83eb23193b7e0f01ae66ff37d30e557e4816be5c16cc6e1048e0adb15cd970e40b983b9d70d29525febac566f4a4a87565b5b2a2737dd4a3e41a18488

diff --git a/sys-apps/polychromatic/polychromatic-0.9.8.ebuild b/sys-apps/polychromatic/polychromatic-0.9.8.ebuild
new file mode 100644
index 000000000000..d6376d0573c8
--- /dev/null
+++ b/sys-apps/polychromatic/polychromatic-0.9.8.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit meson python-single-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="RGB lighting management software for GNU/Linux powered by OpenRazer"
+HOMEPAGE="https://polychromatic.app/
+	https://github.com/polychromatic/polychromatic/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/pyqt6-webengine[${PYTHON_USEDEP}]
+		dev-python/pyqt6[svg,${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/colour[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		sys-apps/openrazer[client,${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-util/intltool
+"
+
+DOC_CONTENTS="To automatically start up Polychromatic on session login copy
+/usr/share/polychromatic/polychromatic-autostart.desktop file into Your user's
+~/.config/autostart/ directory."
+
+src_test() {
+	rm -rf "locale" || die
+	ln -svf "${BUILD_DIR}/locale" "locale" || die
+	PYTHONPATH="tests:${PYTHONPATH}" "${EPYTHON}" "tests/runner.py" || die
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	readme.gentoo_create_doc
+
+	python_doscript "${S}"/polychromatic-{cli,controller,helper,tray-applet}
+
+	# Do not force polychromatic to autostart on session login.
+	# Move it into /usr/share/polychromatic and treat it as an example file
+	# that could be installed into user's ~/.config/autostart/ directory.
+	mv "${ED}/etc/xdg/autostart/${PN}-autostart.desktop" \
+	   "${ED}/usr/share/${PN}/${PN}-autostart.desktop" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}