repo/gentoo:master commit in: dev-python/cappa/

commit:     2d29a1ca0ec5ca19246694d94e6c0695a60b496c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  9 15:59:38 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug  9 15:59:38 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d29a1ca

dev-python/cappa: New package, v0.32.2

New NIH dependency for dev-python/yaxmldiff bump.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cappa/Manifest            |  2 ++
 dev-python/cappa/cappa-0.32.2.ebuild | 49 ++++++++++++++++++++++++++++++++++++
 dev-python/cappa/metadata.xml        | 12 +++++++++
 3 files changed, 63 insertions(+)

diff --git a/dev-python/cappa/Manifest b/dev-python/cappa/Manifest
new file mode 100644
index 000000000000..1bd2c235eb56
--- /dev/null
+++ b/dev-python/cappa/Manifest
@@ -0,0 +1,2 @@
+DIST cappa-0.32.2.tar.gz 361403 BLAKE2B 31a5064ab830db3be913103a92bc5be4a49d16e4def61c36efdd9aeca034bbc7ace1e60e6563e2e555b6298785744b921c3fb8436f2a4051cd238bb27825d08e SHA512 e8284463a9a01d0f5c950181fa40674711de0631761389c8db0bf3255e9c30fbac01a45524ea4df0bd811eeb74078db223720742097bd505205d3d94d4f7ad40
+DIST cappa-0.32.2.tar.gz.provenance 9968 BLAKE2B f4287bf8c1c1895d29ee58292cceacd53cd2fb17272530c548440781c5f5a1f9986fdd8946059f38f6b220304845b61375b72c61c8e13ecd9fe089619af3a15d SHA512 be7aea8e1a8d0f12cbcfdf8cdf2805890c9d31a8f6115c2aaac953939324e57838828b9fa424ad7d0d5cb89c16de4fde5be7f099a40b177240cafb13eab61ed1

diff --git a/dev-python/cappa/cappa-0.32.2.ebuild b/dev-python/cappa/cappa-0.32.2.ebuild
new file mode 100644
index 000000000000..00658140eaf6
--- /dev/null
+++ b/dev-python/cappa/cappa-0.32.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/DanCardin/cappa
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Declarative CLI argument parser"
+HOMEPAGE="
+	https://github.com/DanCardin/cappa/
+	https://pypi.org/project/cappa/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/rich-12.1.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/type-lens-0.2.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+		>=dev-python/docstring-parser-0.17[${PYTHON_USEDEP}]
+		>=dev-python/msgspec-0.19.0[${PYTHON_USEDEP}]
+		>=dev-python/pydantic-1.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# sphinx can't find extension prior to installing the package
+		tests/test_e2e.py::test_docutils
+		# TODO, test env problem
+		tests/help/test_line_wrapping.py::test_line_wraps_correctly_with_terminal_escape_codes
+	)
+
+	local -x COLUMNS=80
+	epytest tests
+}

diff --git a/dev-python/cappa/metadata.xml b/dev-python/cappa/metadata.xml
new file mode 100644
index 000000000000..50b7d061cfeb
--- /dev/null
+++ b/dev-python/cappa/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>[email protected]</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">DanCardin/cappa</remote-id>
+		<remote-id type="pypi">cappa</remote-id>
+	</upstream>
+</pkgmetadata>