repo/gentoo:master commit in: dev-python/pbr/

commit:     b7fa55004b42da0a05039fc00b757623976c73ae
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 14 04:06:03 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug 14 04:21:15 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7fa5500

dev-python/pbr: Bump to 7.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pbr/Manifest         |  1 +
 dev-python/pbr/pbr-7.1.0.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
index 694e9deb1137..5d27394d1aa6 100644
--- a/dev-python/pbr/Manifest
+++ b/dev-python/pbr/Manifest
@@ -1 +1,2 @@
 DIST pbr-7.0.3.tar.gz 135625 BLAKE2B a0271614d745165056a65d6de3673217fe4ae2d3bbc43b0eb7b9d1b07fef4364dc3e5f938ce0db63b9fb5031247a49ccca1be4bbee5ecbc4d53ca6663faaaba1 SHA512 dff6c9ae44cdb8db111d87530a1096dd3f9045df20cb3105f736b909f9dce957e2e8f54d6a8a1c09139689d39b1b3b4dbd53947414e4d467b11314b7f397fb99
+DIST pbr-7.1.0.tar.gz 139971 BLAKE2B 8979814f3653a7c5a459ad1047da4b3b4531ac33bfe31c4133d036799a3c86fae47f4fbc50f7f77d56ba9ba29bcb48be549aedcff6caec929f63612c454d2d7c SHA512 168a380f7a6a83f4f6d62559cd7df46312cdb6fece783d3e499f38ae014d3adfaa4529a25c43c275c73f68b216dc66708e4cf84d670ee4ebf83f4043f9e7b159

diff --git a/dev-python/pbr/pbr-7.1.0.ebuild b/dev-python/pbr/pbr-7.1.0.ebuild
new file mode 100644
index 000000000000..8f4a30dddae7
--- /dev/null
+++ b/dev-python/pbr/pbr-7.1.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{12..15} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-64.0.0[${PYTHON_USEDEP}]
+"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and
+# https://bugs.gentoo.org/show_bug.cgi?id=561038 docutils is needed for sphinx
+# exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848 stestr is run as
+# external tool.
+BDEPEND="
+	${RDEPEND}
+	test? (
+		>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_with_argument:_&:' \
+		-e 's:test_wsgi_script_run:_&:' \
+		-i pbr/tests/functional/test_wsgi_scripts.py || die
+	# installs random packages via pip from the Internet
+	rm pbr/tests/functional/test_pep517.py || die
+	rm pbr/tests/functional/test_requirements.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest -b
+}