repo/gentoo:master commit in: dev-util/diffoscope/

commit:     6e8e84b3f6cbb0f5c394aaf8acdfbfdd4188eb93
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 14 11:59:28 2026 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Aug 14 12:19:34 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e8e84b3

dev-util/diffoscope: add 327

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   2 +
 dev-util/diffoscope/diffoscope-327.ebuild | 151 ++++++++++++++++++++++++++++++
 2 files changed, 153 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index d24f40701cb3..d733361e429c 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -6,3 +6,5 @@ DIST diffoscope-324.tar.bz2 3148903 BLAKE2B 8d2689845098280ec16af12d5cc34eacc844
 DIST diffoscope-324.tar.bz2.asc 833 BLAKE2B 10e3b89fba95d1a770b6fcc899f4bfb0c4898f9a09aeb20e8b38b8a8abe17c8d65f5c32e98b9f32ace5d7a53a378ebf500030fc2e54c1a9b49da217ef6595408 SHA512 0f2136b0e6c8a048938219c833dfd5b05627220e63a996784c71821a41e773186165de95817c6452c92d910b69fd82855727c93d805d46d34de9238174ac565b
 DIST diffoscope-325.tar.bz2 3148621 BLAKE2B 1f6ae9c61697a76af058fd6d81f94334684150634b9eeb1600df997bd9f6be56c64620e3e307601704e0d1a88d68412b0a764dcf27693505d030b96c93f9122c SHA512 54259d844436fc9c178273a07b2effa52ffe48b96de04c6dbebca48bc5651b4bec2d6492ad59fcbe87d027d9efd57892715733b48d3cf0cbaf274159bc1cd197
 DIST diffoscope-325.tar.bz2.asc 833 BLAKE2B d8564a5ab95393b245acf01fe870a9ea136f7e8df113398ef3d887fc25a949b11832710941c0f318da51e8614df75f2234dfcd0b438bc83ea068f33e0375deae SHA512 f6ce6c5fa4e904266bd252678d875e0a3db12e0a9b6f387f3b4367c9a949e438c3148a6915f4b08879e921cda22b7f16061342d6730b9a8e5fc8ae36b291bb30
+DIST diffoscope-327.tar.bz2 3148996 BLAKE2B c39fbb41914edd19824b98c8ac4cb3d669e3764cfd5a9249212379ab78c69340599e1ddf174ccb4e9081fda60f8f605f750b2b9b6ac6f0cc9cbca54d7e3765d7 SHA512 850ef836cf9f84be783483b8b602a9b8da35dff6c0052ebdc24fa7215c646b79b8586d068d59d6c2588994d42855b6f32e90b2f7700229adefc8a73733d2b677
+DIST diffoscope-327.tar.bz2.asc 833 BLAKE2B 32876f406c2a0f02cff837c0878bf3337638c4c649fcc8a4931c71eb0f2f34c8bf99c8df037f8822f02b1f2e59541f6604753d9a9a69ecd6582b090dbf520c8a SHA512 61e7ea0756c6db06d1318f95f36512630774e52d5be700e78b1d007eb8fe732db09bbf419b6b78ec689f55277832821659da1a95bb343cd9c7dbeb2b582b2035

diff --git a/dev-util/diffoscope/diffoscope-327.ebuild b/dev-util/diffoscope/diffoscope-327.ebuild
new file mode 100644
index 000000000000..e3579768c026
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-327.ebuild
@@ -0,0 +1,151 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="ncurses"
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/chrislamb.asc
+inherit distutils-r1 optfeature toolchain-funcs verify-sig
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="
+	https://diffoscope.org/archive/${P}.tar.bz2
+	verify-sig? ( https://diffoscope.org/archive/${P}.tar.bz2.asc )
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java libguestfs llvm
+lzma mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		|| (
+			dev-python/python-magic[${PYTHON_USEDEP}]
+			sys-apps/file[python,${PYTHON_USEDEP}]
+		)
+		dev-python/libarchive-c[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/python-tlsh[${PYTHON_USEDEP}]
+		hdf5? ( dev-python/h5py[${PYTHON_USEDEP}] )
+		pdf? ( dev-python/pypdf[${PYTHON_USEDEP}] )
+	')
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-alternatives/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	libguestfs? ( app-emulation/libguestfs[python,${PYTHON_SINGLE_USEDEP}] )
+	llvm? ( llvm-core/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm[python,${PYTHON_SINGLE_USEDEP}] )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		|| (
+			>=app-arch/7zip-24.09[symlink(+)]
+			app-arch/p7zip
+		)
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-chrislamb )
+"
+
+EPYTEST_DESELECT=(
+	# Presumably needs Gentoo specific handling for "nonexistent" like the rest already have
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Slightly different diff output presentation vise
+	tests/comparators/test_fsimage.py::test_differences
+	tests/comparators/test_fsimage.py::test_differences_fat
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_test() {
+	case $(tc-get-ptr-size) in
+		4)
+			EPYTEST_IGNORE+=(
+				# Needs fixing in Perl itself (bug #934443)
+				tests/comparators/test_epub.py
+				tests/comparators/test_zip.py
+			)
+			;;
+		*)
+			;;
+	esac
+
+	distutils-r1_src_test
+}
+
+pkg_postinst() {
+	optfeature "show an approximate progress bar" dev-python/progressbar2
+}