repo/gentoo:master commit in: dev-python/tpm2-pytss/

commit:     525e03808bcedc23ee4937d053e59e158a5477cc
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 17 04:56:08 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Aug 17 05:42:16 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=525e0380

dev-python/tpm2-pytss: Bump to 3.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tpm2-pytss/Manifest                |  1 +
 dev-python/tpm2-pytss/tpm2-pytss-3.0.0.ebuild | 49 +++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/tpm2-pytss/Manifest b/dev-python/tpm2-pytss/Manifest
index 36ebe54c2e95..a4d04ee7a3ce 100644
--- a/dev-python/tpm2-pytss/Manifest
+++ b/dev-python/tpm2-pytss/Manifest
@@ -1 +1,2 @@
 DIST tpm2-pytss-2.3.0.tar.gz 213848 BLAKE2B 7e9264ab53cfe666991150fe2c0efdd973f7b58b4968b557d6494156ba4d362bd147f580f2ef50b85ac1b43cd9fc4921d71eea42d5a14b9379f82d45b6a6b536 SHA512 d0f76aec77afa773ec0ed7878a0ca4ef3b3475aa64f219d7a5afd89cbca795457536b0a9b5ffa14704200dcb35a89df36f9fc799694f7cc3cfbf98ea551628b1
+DIST tpm2_pytss-3.0.0.tar.gz 215519 BLAKE2B 3c6cb3bdb43bb4b7264569c7474f999163d79e0de9207d4146f2f087f77e731113260d265cf4ef8ef3e15e09ef45c9e4ce5f391df339e0636e2f8390954c15d3 SHA512 c69245c6bdc5a92884c8267c3de79570880bfc2498f31bddfdb03ad21aac7932327d4d28d93bc5de6d47c99397d411a8b4c11566311a166fe4648d47cab5bad4

diff --git a/dev-python/tpm2-pytss/tpm2-pytss-3.0.0.ebuild b/dev-python/tpm2-pytss/tpm2-pytss-3.0.0.ebuild
new file mode 100644
index 000000000000..969d212b5ccf
--- /dev/null
+++ b/dev-python/tpm2-pytss/tpm2-pytss-3.0.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings for TSS"
+HOMEPAGE="
+	https://pypi.org/project/tpm2-pytss/
+	https://github.com/tpm2-software/tpm2-pytss/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+fapi test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-crypt/tpm2-tss:=[fapi=]
+	fapi? ( >=app-crypt/tpm2-tss-3.0.3:= )
+	test? ( app-crypt/swtpm )
+"
+RDEPEND="${DEPEND}
+	dev-python/cffi[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-47[${PYTHON_USEDEP}]
+	dev-python/pycparser[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Current tpm2-tss specified a newer revision that the one tested for
+		test/test_encoding.py::ToolsTest::test_tools_decode_tpml_tagged_tpm_property
+	)
+	epytest
+}