repo/gentoo:master commit in: app-misc/fastfetch/

commit:     8da99b42215bad8b3adb425e8934e8c4ce9a873c
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 17 11:24:16 2026 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Mon Aug 17 11:44:06 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8da99b42

app-misc/fastfetch: add 2.67.1

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.67.1.ebuild | 154 +++++++++++++++++++++++++++++
 2 files changed, 155 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 8463de1aaf9e..7b8a08a48825 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -2,3 +2,4 @@ DIST fastfetch-2.61.0.tar.gz 1452448 BLAKE2B 1fabd1830fea19d764727e678340456c519
 DIST fastfetch-2.63.1.tar.gz 1477073 BLAKE2B 1a15944a77c95c571e519c85aece5abddc1bcaaaa67506214ed3ec47a55acb19e7f6608f81e02dab4643c1574151760192a1ea7665ff5db6d58850934825d92d SHA512 ff92fe75c29a3418052cf48475eaa08d697825fc41e4d36bab46cfcd91a8f704bde7dae6cacfb6af272be4040fd101bcc5ef7e235540a7427102073d70607464
 DIST fastfetch-2.65.2.tar.gz 1555551 BLAKE2B c5319784aee7f66beb03c043562124ce162c40082099592f37cea5f8dc96583eed995305f392b29affa9f9dc139a0b1dea8d9e589600699953cb396eff73a9b6 SHA512 750b6ea174fe37f0c232ee2d0d76c7c8696c9c25b27a35bc36f598ffa52a165f3a6dca0390cbac1f00c1a1b304e3e8ef1bf5a433e79932f179c4d0b48550dbbf
 DIST fastfetch-2.67.0.tar.gz 1571161 BLAKE2B b41b517ab0a102b5b10f522a4434cbd006809474962cbc71de1dc6e88281f3224d865385a18c0d28ff959cd7c64e59e72539620f540637c4cb4d2ff4d9a36f50 SHA512 512f2ca492686d6990dc440ddc4240c6922510c7dce6669caf6095d859797483fdcf83ecb1993c9b3c0bd1f8e8e1cca49348bbb24c361d9c02a6deed7d15f6be
+DIST fastfetch-2.67.1.tar.gz 1573878 BLAKE2B ff59b9af59008f6e9b4141308bc5b2d7fa44014dd5831d0fc00190fe723dc9f5803f8083feca3c6535237bc80d4fea6a363b09f317d76e480207c309cca493c3 SHA512 b1cc5eba51073471deabaae1f9d8af48218a6ddd2468666bd1826a19da6aa26b8a997ed5a0d06f2e626008bb2a58d1a0c44eb67795c10c4ebc1a3774cf7743d2

diff --git a/app-misc/fastfetch/fastfetch-2.67.1.ebuild b/app-misc/fastfetch/fastfetch-2.67.1.ebuild
new file mode 100644
index 000000000000..bda7ddcde8df
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.67.1.ebuild
@@ -0,0 +1,154 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{3..4} )
+inherit cmake flag-o-matic lua-single
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm efl elf gnome imagemagick lua opencl opengl pulseaudio sqlite test vaapi vdpau vulkan wayland xcb xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.12.0
+	sys-apps/hwdata
+	virtual/zlib:=
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	lua? ( ${LUA_DEPS} )
+	opencl? ( virtual/opencl )
+	opengl? (
+		media-libs/libglvnd[X?]
+		X? ( x11-libs/libX11 )
+	)
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vaapi? ( media-libs/libva:=[X?] )
+	vdpau? ( x11-libs/libvdpau )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	efl? ( dev-libs/efl )
+	opengl? ( X? ( x11-base/xorg-proto ) )
+	xcb? ( x11-base/xorg-proto )
+	xrandr? ( x11-base/xorg-proto )
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	chafa? ( imagemagick )
+	lua? ( ${LUA_REQUIRED_USE} )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.64.1-cmake_lua_version.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local glx=no
+	if use X; then
+		if use opengl; then
+			glx=yes
+		else
+			ewarn 'USE="X" adds GLX support for USE="opengl"'
+			ewarn 'This build with USE="X -opengl" will not include any extra X support.'
+		fi
+	fi
+
+	local mycmakeargs=(
+		# requires >=dev-libs/quickjs-ng-0.15
+		-DENABLE_QUICKJS=no
+
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+		-DBUILD_FLASHFETCH=no
+		-DPACKAGES_REMOVE_DISABLED=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EET=$(usex efl)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=${glx}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VADRM=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	if use vaapi && use X; then
+		mycmakeargs+=( -DENABLE_VAX11=1 )
+	else
+		mycmakeargs+=( -DENABLE_VAX11=0 )
+	fi
+
+	if use lua; then
+		mycmakeargs+=(
+			-DLUA_VERSION="$(lua_get_version)"
+		)
+	fi
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}