repo/gentoo:master commit in: dev-qt/qtpositioning/

commit:     3faaf022c10e5a8baae8b49731e53d1d1ceba7e9
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 18 11:15:23 2026 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Aug 18 11:40:33 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3faaf022

dev-qt/qtpositioning: add 6.11.2

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 dev-qt/qtpositioning/Manifest                    |  1 +
 dev-qt/qtpositioning/qtpositioning-6.11.2.ebuild | 68 ++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-qt/qtpositioning/Manifest b/dev-qt/qtpositioning/Manifest
index 7cd007bc03d8..c38ffd6dd8bd 100644
--- a/dev-qt/qtpositioning/Manifest
+++ b/dev-qt/qtpositioning/Manifest
@@ -1 +1,2 @@
 DIST qtpositioning-everywhere-src-6.11.1.tar.xz 653096 BLAKE2B 4d333b537321d9e5f58c41df5784263eb2639c7e149a0fad8129379c8eecec80abc7daad0c3d541fa734edbab794f11c9e3baab3d7ca099f07ed41105e3d6f20 SHA512 b39c05c13c6440e9d3dd85577ac8e56751f1db598c3ef5f8cdd71d379291abb8d80dd900e5bcde83310d071c398e4dc7de7741d4523d3675806b69bce0a5129a
+DIST qtpositioning-everywhere-src-6.11.2.tar.xz 655468 BLAKE2B ecd587041e094c776804768cba9969906d9c9e37e31cbad4b35f30cb5970301d06215a594507270bffab98fd7b4035ba27acb03f0339161d905b3f282c544719 SHA512 35ceb7f5a365423e27e95fab8f5ace4968b0cf3cb658f9070509ac1c3704043b7f000b8a146cc99263cd3a7bc2101983c9231e3f80d1831a3eaa322b754edcd1

diff --git a/dev-qt/qtpositioning/qtpositioning-6.11.2.ebuild b/dev-qt/qtpositioning/qtpositioning-6.11.2.ebuild
new file mode 100644
index 000000000000..71a62d763abe
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-6.11.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Physical position determination library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="geoclue nmea +qml"
+
+DEPEND="
+	~dev-qt/qtbase-${PV}:6
+	geoclue? ( ~dev-qt/qtbase-${PV}:6[dbus] )
+	nmea? (
+		~dev-qt/qtbase-${PV}:6[network]
+		~dev-qt/qtserialport-${PV}:6
+	)
+	qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+"
+RDEPEND="
+	${DEPEND}
+	geoclue? ( app-misc/geoclue:2.0 )
+"
+
+CMAKE_SKIP_TESTS=(
+	# threads test (rarely) fails randomly
+	tst_qgeoareamonitor
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	# unfortunately cmake_use_find_package would break things with qtbase
+	use geoclue ||
+		sed -e 's/TARGET Qt::DBus/FALSE/' \
+			-i src/plugins/position/CMakeLists.txt || die
+	use nmea ||
+		sed -e 's/TARGET Qt::Network/FALSE/' \
+			-i src/plugins/position/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package qml Qt6Qml)
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_LIBDIR}"/cmake/Qt6Positioning/*DummyPlugin*.cmake
+			"${D}${QT6_LIBDIR}"/cmake/Qt6Positioning/*TestPlugin*.cmake
+			"${D}${QT6_PLUGINDIR}"/position/libqtposition_satellitesourcetest.so
+			"${D}${QT6_PLUGINDIR}"/position/libqtposition_testplugin{,2}.so
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}