repo/proj/guru:dev commit in: net-voip/baresip/

commit:     f285f9c30aa5e5e502b9faa58b9b981ef02d3d3f
Author:     Dale Showers <gentoo <AT> fictx <DOT> com>
AuthorDate: Tue Aug 18 13:02:32 2026 +0000
Commit:     Dale Showers <gentoo <AT> fictx <DOT> com>
CommitDate: Tue Aug 18 13:06:00 2026 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=f285f9c3

net-voip/baresip: add 4.10.0

Signed-off-by: Dale Showers <gentoo <AT> fictx.com>

 net-voip/baresip/Manifest              |   1 +
 net-voip/baresip/baresip-4.10.0.ebuild | 109 +++++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/net-voip/baresip/Manifest b/net-voip/baresip/Manifest
index 18a1329fe4..615fbc9c5c 100644
--- a/net-voip/baresip/Manifest
+++ b/net-voip/baresip/Manifest
@@ -1 +1,2 @@
+DIST baresip-4.10.0.tar.gz 1207390 BLAKE2B 1b2401b344bbc2625e135b81c6b86ee9f5cea725249346302d0690e31048be335f095e1cba84ffd7d59ffc943d99208c1f2d1992aac8752d96f6667467af50bb SHA512 bca9b82695dceca2bf2dabe39343d4a04522f1a3e3355e2e7ad26add7a85000e36df899fd8e5d864037520bc6a3c06e1e200567af38925273ace68d39994a87b
 DIST baresip-4.8.0.tar.gz 1208334 BLAKE2B d6aa11e6fce005da222f46f538fb33fe63176615c5a4391c7d034f128d34d2626711e10b8113af8f982a6b15389df0039419d2b110879d7b8a120aa175193d5c SHA512 7116f5a4a2239875a2c3a9a9d376d8c7c3eb0d9ce7330c64ca4f3db89e1672f0c0848a4860cd31dd5b07b565487e96fc95b651fff4a6dfb1e8d77fe607697ecd

diff --git a/net-voip/baresip/baresip-4.10.0.ebuild b/net-voip/baresip/baresip-4.10.0.ebuild
new file mode 100644
index 0000000000..a44c402e7f
--- /dev/null
+++ b/net-voip/baresip/baresip-4.10.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Baresip is a portable and modular SIP User-Agent"
+HOMEPAGE="https://github.com/baresip/baresip"
+SRC_URI="https://github.com/baresip/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="aac acip alsa amr aptx aom codec2 console dbus echo evdev ffmpeg gstreamer
+	  gtk3 jack httpd httpreq mpa mqtt opus pipewire portaudio pulseaudio sdl
+	  serreg snapshot sndfile spandsp static-libs syslog tcpcontrol v4l video vpx webrtc X"
+
+RE_PVF="$(ver_cut 1-2)*"
+
+DEPEND="
+	dev-libs/openssl:0=
+	=net-voip/re-${RE_PVF}
+	virtual/zlib:=
+	aac? ( media-libs/fdk-aac )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	aom? ( media-libs/libaom )
+	aptx? ( media-libs/libopenaptx )
+	codec2? ( media-libs/codec2 )
+	dbus? (
+		dev-util/gdbus-codegen
+		sys-apps/dbus
+	)
+	ffmpeg? ( media-video/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0
+	)
+	gtk3? ( x11-libs/gtk+:3 )
+	jack? ( virtual/jack )
+	mpa? (
+		media-sound/twolame
+		media-sound/mpg123
+		media-libs/speexdsp
+	)
+	mqtt? ( app-misc/mosquitto )
+	opus? ( media-libs/opus )
+	pipewire? ( media-video/pipewire )
+	snapshot? ( media-libs/libpng )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sdl? ( media-libs/libsdl2 )
+	sndfile? ( media-libs/libsndfile )
+	spandsp? ( media-libs/spandsp )
+	v4l? ( media-libs/libv4l )
+	vpx? ( media-libs/libvpx )
+	webrtc? ( media-plugins/gst-plugins-webrtc )
+	X? ( x11-libs/libX11 )
+	"
+
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	use aac && MODULES+="aac;"
+	use acip && MODULES+="ebuacip;"
+	use alsa && MODULES+="alsa;"
+	use amr && MODULES+="amr;"
+	use aom && MODULES+="av1;"
+	use aptx && MODULES+="aptx;"
+	use codec2 && MODULES+="codec2;"
+	use console && MODULES+="cons;"
+	use dbus && MODULES+="ctrl_dbus;"
+	use evdev && MODULES+="evdev;"
+	use echo && MODULES+="echo;"
+	use gtk3 && MODULES+="gtk;"
+	use gstreamer && MODULES+="gst;"
+	use httpd && MODULES+="httpd;"
+	use httpreq && MODULES+="httpreq;"
+	use ffmpeg && MODULES+="avcodec;avfilter;avformat;selfview;swscale;"
+	use jack && MODULES+="jack;"
+	use mpa && MODULES+="mpa;"
+	use mqtt && MODULES+="mqtt;"
+	use opus && MODULES+="opus;opus_multistream;"
+	use pipewire && MODULES+="pipewire;"
+	use pulseaudio && MODULES+="pulse;"
+	use portaudio && MODULES+="portaudio;"
+	use serreg && MODULES+="serreg;"
+	use snapshot && MODULES+="snapshot;"
+	use sdl && MODULES+="sdl;"
+	use sndfile && MODULES+="sndfile;"
+	use spandsp && MODULES+="g722;plc;"
+	use syslog && MODULES+="syslog;"
+	use tcpcontrol && MODULES+="ctrl_tcp;"
+	use v4l && MODULES+="v4l2;"
+	use video && MODULES+="vidbridge;vidinfo;"
+	use vpx && MODULES+="vp8;vp9;"
+	use webrtc && MODULES+="webrtc_aec;"
+	use X && MODULES+="x11;"
+	MODULES+="account;aubridge;auconv;aufile;auresamp;ausine;contact;debug_cmd;dtls_srtp;g711;ice;menu;mixausrc;mixminus;mwi;natpmp;netroam;pcp;presence;turn;rtcpsummary;srtp;stdio;stun;uuid;vumeter"
+
+	local mycmakeargs=(
+		-DMODULES="$MODULES"
+		-DSTATIC=$(usex static-libs ON OFF)
+	)
+	cmake_src_configure
+}