repo/gentoo:master commit in: www-client/opera-gx/

commit:     f5895236c17043afd12189634c1545a825e59550
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 18 21:54:27 2026 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Wed Aug 19 02:44:30 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5895236

www-client/opera-gx: automated bump (134.0.5954.67)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-gx/Manifest                      |   1 +
 www-client/opera-gx/opera-gx-134.0.5954.67.ebuild | 137 ++++++++++++++++++++++
 2 files changed, 138 insertions(+)

diff --git a/www-client/opera-gx/Manifest b/www-client/opera-gx/Manifest
index 27aecd1b4b4e..dbbf750f130d 100644
--- a/www-client/opera-gx/Manifest
+++ b/www-client/opera-gx/Manifest
@@ -1,2 +1,3 @@
 DIST opera-gx-stable_129.0.5823.49_amd64.deb 171528384 BLAKE2B 894d19191c5aa1c013b9d771b94aabd3d3572b360dbf045b80b2d539ed164102d94f7a6e51c166bd10bb1d07f3646f9a50779a1a126b188c68f9c864b5905384 SHA512 d729a02ec272507457a8fe5133237596b72e35ac5bfba202838280344523af69d2d1e709987245cb301b55274684ac0dd6dbdd3552cc0909db06a6572bb71f42
 DIST opera-gx-stable_129.0.5823.64_amd64.deb 171535160 BLAKE2B 6ebe949a672eaad8cc8c3dfa4634c419e6a9bad1c9b25d82753ddd352a7ce7e9fe6fcf7ffdd77e29733ea88f610eb9a68eb90a6bfb2da496ceb8576000d10935 SHA512 9e3cade9624e18654cdda1f4e24ec2175d4178e4f529c1e28cab51996a58a9aff7dbcf088518b6f2f5f85caafbafaf4457a5c911a07032a32d602c2ca1d35148
+DIST opera-gx-stable_134.0.5954.67_amd64.deb 179729656 BLAKE2B 3c8d95bba4ccf3b514c98d4f78a24c7dc1cddea053774052b2acb3f6f9af344582a631d672940d0f1ef4f6a90e02957d23a6ca143d243c7356dc6943fce31423 SHA512 70d7930245e43f269a2a8dc891d77cd378f9ac3fe2523d846697810e06b90d128a12522df0af122d5822cdbc7ec6512311cb781d4f5de1e61ada215103f0b02b

diff --git a/www-client/opera-gx/opera-gx-134.0.5954.67.ebuild b/www-client/opera-gx/opera-gx-134.0.5954.67.ebuild
new file mode 100644
index 000000000000..35a2fbbb6ba2
--- /dev/null
+++ b/www-client/opera-gx/opera-gx-134.0.5954.67.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+inherit chromium-2 pax-utils unpacker xdg
+
+DESCRIPTION="Opera, but for 'gamers'"
+HOMEPAGE="https://www.opera.com/gx"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN//-/_}"
+	"https://download2.operacdn.com/pub/${PN//-/_}"
+	"https://download3.operacdn.com/pub/${PN//-/_}"
+	"https://download4.operacdn.com/pub/${PN//-/_}"
+)
+
+if [[ ${PN} == opera-gx ]]; then
+	MY_PN=${PN}-stable
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# or use Chromicler to handle bumps.
+# Does not _need_ to be updated for every new version of Opera, only when it breaks.
+CHROMIUM_VERSION="150"
+SRC_URI="${SRC_URI_BASE[*]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2020"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/${MY_PN}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir opt || die
+	mv "usr/lib/x86_64-linux-gnu/${MY_PN}" "${OPERA_HOME}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/opera_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/opera" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	rm "${OPERA_HOME}/libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}