Re: [XSL SORT] utilisation d'un paramètre / clé de tri

Bonjour,
Le mercredi 22 mars 2006 à 14:26 +0100, RACHOVITCH Yoni a écrit :
> Merci
> 
> en utilisant quelques balises <xsl:if...> et votre proposition, je
> peux rendre mes tris "plus dynamiques".

Tout à fait.

Dans certains cas, il est également possible de contourner cela en
utilisant des clés.

Si par exemple vous vous restreignez à des expressions XPath simples du
type foo/bar/baz avec uniquement des éléments et un maximum de trois
niveau; vous pourriez écrire :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:param name="field">baz/bat/baz</xsl:param>
    <xsl:key name="k1" match="/*/*/*" use="name()"/>
    <xsl:key name="k2" match="/*/*/*/*" use="concat(name(..), '/', name())"/>
    <xsl:key name="k3" match="/*/*/*/*/*" use="concat(name(../..), '/', name(..), '/', name())"/>
    <xsl:template match="/">
        <tri>
            <xsl:apply-templates select="/*/*">
                <xsl:sort
                    select="key(concat('k', string-length($field) - string-length(translate($field, '/', '')) +1 ), $field)[count(ancestor::*|current()) = count(ancestor::*)]"
                />
            </xsl:apply-templates>
        </tri>
    </xsl:template>
    <xsl:template match="*">
        <xsl:copy>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

(à adapter à votre contexte).

Ce n'est néanmoins ni très lisible ni facile à maintenir!

> D'ailleurs est-il possible de faire un <xsl:sort> non pas sur un
> noeud, mais sur une variable, comme par exemple, la concaténation de
> plusieurs noeuds (Prénom + Nom par exemple)?

Sur une variable, non, mais sur une fonction sans problème.

<xsl:sort select="concat(nom, ' ', prenom)"/>

Par contre, intégrer cela dans votre mécanisme de tris "plus dynamiques"
risque d'être exercice intéressant si vous voulez rester générique!

Une solution intermédiaire peut être d'adopter des conventions qui vous
serons propres pour désigner certaines fonctions prédéfinies (#nomPrenom
pour concat(nom, ' ', prenom) par exemple).

Cordialement,

Eric van der Vlist

-- 
GPG-PGP: 2A528005
Curious about Relax NG? Read my book online.
                                   http://books.xmlschemata.org/relaxng/
------------------------------------------------------------------------
Eric van der Vlist       http://xmlfr.org            http://dyomedea.com
(ISO) RELAX NG   ISBN:0-596-00421-4 http://oreilly.com/catalog/relax
(W3C) XML Schema ISBN:0-596-00252-1 http://oreilly.com/catalog/xmlschema
------------------------------------------------------------------------


-- Attached file included as plaintext by Ecartis --

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.1 (GNU/Linux)

iD8DBQBEIWD1Dvn+ZCpSgAURAsnuAKCSG7wHxO/g7zVR/TkIgdiXvl0tawCgjCIL
RkyLSi4LZIg/tosGr8ig1jA=
=JoK5
-----END PGP SIGNATURE-----