Re: [meta-arago][scarthgap/master][PATCH] meta-arago-test: Add CoreMark CPU benchmark

Hi Sadik, 
On 14:58-20251028, Sadik via lists.yoctoproject.org wrote:
> From: sadik <[email protected]>
> 
> Add CoreMark benchmark recipe to measure CPU
> performance on TI platforms,Integrate CoreMark
> into ti-test package group alongside arm-benchmarks.
> 
> CoreMark is an industry-standard CPU benchmark from EEMBC
> (Embedded Microprocessor Benchmark Consortium) that provides 
> a standardized method to test the performance of processors.
> 
> Signed-off-by: sadik <[email protected]>
> ---
>  .../recipes-benchmark/coremark/coremark.bb    | 24 +++++++++++++++++++
>  .../recipes-core/packagegroups/ti-test.bb     |  1 +
>  2 files changed, 25 insertions(+)
>  create mode 100644 meta-arago-test/recipes-benchmark/coremark/coremark.bb
> 
> diff --git a/meta-arago-test/recipes-benchmark/coremark/coremark.bb b/meta-arago-test/recipes-benchmark/coremark/coremark.bb
> new file mode 100644
> index 00000000..330adeda
> --- /dev/null
> +++ b/meta-arago-test/recipes-benchmark/coremark/coremark.bb
> @@ -0,0 +1,24 @@
> +SUMMARY = "The benchmark utility to measure the performance of CPU"
> +
> +LICENSE = "CLOSED"
> +LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0a18b17ae63deaa8a595035f668aebe1"
> +

AFAIR CoreMark uses Apache 2.0 license. LICENSE = "CLOSED" contradicts the LIC_FILES_CHKSUM entry.

> +SRC_URI = "git://github.com/eembc/coremark.git;branch=main;protocol=https"
> +SRCREV = "d5fad6bd094899101a4e5fd53af7298160ced6ab"
> +
> +S = "${WORKDIR}/git"
> +TARGET_CC_ARCH += "${LDFLAGS}"

Above line incorrectly adds LDFLAGS to TARGET_CC_ARCH, using  oe_runmake
instead of `make compile` should handle the LDFLAGS. Best to remove it.

> +
> +do_compile() {
> +	make compile

`make compile` ignores Yocto's toolchain variables. Best to use oe_runmake 
instead. 

> +}
> +
> +do_install() {
> +	install -d ${D}${bindir}
> +	install -m 0755 coremark.exe ${D}${bindir}
> +	mv ${D}${bindir}/coremark.exe ${D}${bindir}/coremark

Here you are copying the coremark.exe and then renaming it, you can do
it all in one go using install. 

for eg: install -m 0755 coremark.exe ${D}${bindir}/coremark 

Additionally you are assuming that the coremark.exe will 
always be present in the current working dir, best practice is 
to mention the correct path using the Yocto variables.

for eg: install -m 0755 ${S}/coremark.exe ${D}${bindir}/coremark

> +}
> +
> +COMPATIBLE_HOST = '(i.86|x86_64|arm|aarch64).*-linux'
> +
> +SRC_URI[sha256sum] = "d003ed54134a0d365c0d5d8dc828432d610d1d1f77b8f58457cf1e599ad13f17"

SRC_URI[sha256sum] is for tarballs, not git fetchers. It would be best to remove it entirely.

> diff --git a/meta-arago-test/recipes-core/packagegroups/ti-test.bb b/meta-arago-test/recipes-core/packagegroups/ti-test.bb
> index c1166bc2..2c4b097e 100644
> --- a/meta-arago-test/recipes-core/packagegroups/ti-test.bb
> +++ b/meta-arago-test/recipes-core/packagegroups/ti-test.bb
> @@ -88,6 +88,7 @@ TI_TEST_BASE:append:armv7ve = " \
>  #    timestamping
>  TI_TEST_TI_TOOLS = " \
>      arm-benchmarks \
> +    coremark \
>      arm-ddr-bandwidth \
>      cpuloadgen \
>      input-utils \
> -- 
> 2.34.1
> 
> 
> 
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#16707): https://lists.yoctoproject.org/g/meta-arago/message/16707
> Mute This Topic: https://lists.yoctoproject.org/mt/115990643/9980049
> Group Owner: [email protected]
> Unsubscribe: https://lists.yoctoproject.org/g/meta-arago/unsub [[email protected]]
> -=-=-=-=-=-=-=-=-=-=-=-
> 
>
- Yogesh