Re: [meta-arago] [master][RFC PATCH] packagegroup-arago-tisdk-connectivity: Enable zeroconf ip support

On 16:33-20260119, vishnu singh via lists.yoctoproject.org wrote:
> From: Vishnu Singh <[email protected]>
> 
> Dante DEP useage zeroconf for Dante network IP addresses.
> Zeroconf provide the IP network without manual configuation,
> and avahi-autoipd is for auto ip assignment.
> To get the zeroconf ip at bootup, zeroconf-autoip service is used.
There are few typos in description. useage -> usage and configuation ->
configuration. 
> 
> Signed-off-by: Vishnu Singh <[email protected]>
> ---
>  .../zeroconf-autoip/zeroconf-autoip.bb        | 30 +++++++++++++++++++
>  .../zeroconf-autoip/zeroconf-autoip/README    |  1 +
>  .../zeroconf-autoip/[email protected]  | 12 ++++++++
>  .../packagegroup-arago-tisdk-connectivity.bb  |  7 +++++
>  4 files changed, 50 insertions(+)
>  create mode 100644 meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip.bb
>  create mode 100644 meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/README
>  create mode 100644 meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/[email protected]
> 
> diff --git a/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip.bb b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip.bb
> new file mode 100644
> index 00000000..4b59a7e6
> --- /dev/null
> +++ b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip.bb
> @@ -0,0 +1,30 @@
> +SUMMARY = "Zerconf autoip"
Typo Zerconf -> Zeroconf.
> +DESCRIPTION = "Zeroconf IP assignment using avahi autoipd"
> +LICENSE = "MIT"
README file contains TI-TFL, It is a bit confusing due to 2 different
licenses mentioned. Can you clarify the correct license and include
the correct license text in the README. 
> +LIC_FILES_CHKSUM = "file://README;md5=102e8ceedf1b96837ba2eefc0d47f4e6"
> +
> +FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
> +
> +COMPATIBLE_MACHINE = "am62dxx"
> +
> +SRC_URI = "file://[email protected] \
> +	file://README \
> +"
> +
> +S = "${UNPACKDIR}"
> +
> +inherit systemd
> +
> +SYSTEMD_SERVICE:${PN} = "[email protected] [email protected]"
> +SYSTEMD_AUTO_ENABLE = "enable"
> +
> +do_install() {
> +	install -d ${D}${systemd_system_unitdir}
> +	install -m 0644 ${WORKDIR}/[email protected] ${D}${systemd_system_unitdir}/
> +}
> +
> +FILES:${PN}= " \
> +	${systemd_system_unitdir} \
> +	${systemd_system_unitdir}/[email protected] \
> +"
systemd bbclass automatically handles service files, I think it is safe
to drop the FILES variable completely. 
> +PR = "r0"
> diff --git a/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/README b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/README
> new file mode 100644
> index 00000000..1ad1d419
> --- /dev/null
> +++ b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/README
> @@ -0,0 +1 @@
> +TI-TFL
> diff --git a/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/[email protected] b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/[email protected]
> new file mode 100644
> index 00000000..952a8c60
> --- /dev/null
> +++ b/meta-arago-distro/recipes-connectivity/zeroconf-autoip/zeroconf-autoip/[email protected]
> @@ -0,0 +1,12 @@
> +[Unit]
> +Description=zerocnf-autoipd for %i interface
> +After=network.target
> +
> +[Service]
> +ExecStart=/usr/sbin/avahi-autoipd --force-bind %i
> +ExecStop=/usr/sbin/avahi-autoipd -k %i
> +Restart=on-failure
> +RestartSec=30
> +
> +[Install]
> +WantedBy=multi-user.target
> diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-connectivity.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-connectivity.bb
> index 0a8d4493..66aa4872 100644
> --- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-connectivity.bb
> +++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-connectivity.bb
> @@ -53,6 +53,11 @@ BT_TI = "\
>      bt-enable \
>      bt-fw \
>  "
> +ZEROCONF_TI = "\
> +	zeroconf \
> +	avahi-autoipd \
Since services in zeroconf-autoip uses avahi-autoipd, best to include
avahi-autoipd as RDEPENDS in zeroconf-autoip recipe.
> +	zeroconf-autoip \
> +"
>  
>  CONNECTIVITY_RDEPENDS = " \
>      htop \
> @@ -68,6 +73,8 @@ CONNECTIVITY_RDEPENDS = " \
>  CONNECTIVITY_RDEPENDS:append:ti33x = " ${BT_TI}"
>  CONNECTIVITY_RDEPENDS:append:ti43x = " ${BT_TI}"
>  CONNECTIVITY_RDEPENDS:append:am57xx = " ${BT_TI}"
> +CONNECTIVITY_RDEPENDS:append:am62dxx = " ${ZEROCONF_TI}"
> +
>  
>  RDEPENDS:${PN} = "\
>      ${CONNECTIVITY_RDEPENDS} \
> -- 
> 2.50.1
> 
> 
> 
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#16997): https://lists.yoctoproject.org/g/meta-arago/message/16997
> Mute This Topic: https://lists.yoctoproject.org/mt/117382985/9980049
> Group Owner: [email protected]
> Unsubscribe: https://lists.yoctoproject.org/g/meta-arago/unsub [[email protected]]
> -=-=-=-=-=-=-=-=-=-=-=-

Thanks 
Yogesh