Re: Smoking 9063 for HP-UX 11.00, HP-UX 10.20, AIX 4.3 *and* AIX 4.2

For those smoking multiple systems, this might be helpful:
(latest mktest will be at http://home.hccnet.nl/h.m.brand/mktest shortly)

On Wed, 7 Mar 2001 11:52:40 -0600, Jarkko Hietaniemi <[email protected]> wrote:
> Really neat table.   Does your script do this automatically?

Now it does (script attached).

Automated smoke report for patch 9081

O = OK
o = OK (but skipped, cause tested in an earlier configuration)
- = not tested (cause unable to build)
F = Failure(s), extended report at the bottom
  left  letter for PERLIO = stdio,
  right letter for PERLIO = perlio

HP-UX HP-UX  AIX   AIX
11.00 10.20  4.3   4.2  Configuration
----- ----- ----- ----- --------------------------------------------------------------------
 O O   O O   O O   O O  -Uuseperlio
 O O   O O   O O   O O  -Duseperlio
 O O   - -   O O   - -  -Duseperlio -Duse64bitint
 O O   - -   - -   - -  -Duseperlio -Duse64bitall
 o o   o o   O O   F F  -Duseperlio -Duselongdouble
 o o   o o   F F   - -  -Duseperlio -Dusemorebits
 o o   o o   - -   - -  -Duseperlio -Duse64bitall -Duselongdouble
 O O   O O   O O   F F  -Uuseperlio -Dusethreads -Duseithreads
 O O   O O   O O   F F  -Duseperlio -Dusethreads -Duseithreads
 O O   - -   O O   - -  -Duseperlio -Duse64bitint -Dusethreads -Duseithreads
 O O   - -   - -   - -  -Duseperlio -Duse64bitall -Dusethreads -Duseithreads
 o o   o o   O O   F F  -Duseperlio -Duselongdouble -Dusethreads -Duseithreads
 o o   o o   F F   - -  -Duseperlio -Dusemorebits -Dusethreads -Duseithreads
 o o   o o   - -   - -  -Duseperlio -Duse64bitall -Duselongdouble -Dusethreads -Duseithreads

AIX 4.2      stdio    -Duseperlio -Duselongdouble
    pragma/overload.......FAILED at test 153

AIX 4.2      perlio   -Duseperlio -Duselongdouble
    pragma/overload.......FAILED at test 153

AIX 4.3      stdio    -Duseperlio -Dusemorebits
    op/numconvert.........FAILED at test 117

AIX 4.3      perlio   -Duseperlio -Dusemorebits
    op/numconvert.........FAILED at test 117

AIX 4.2      stdio    -Uuseperlio -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28

AIX 4.2      perlio   -Uuseperlio -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28

AIX 4.2      stdio    -Duseperlio -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28

AIX 4.2      perlio   -Duseperlio -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28

AIX 4.2      stdio    -Duseperlio -Duselongdouble -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28
    pragma/overload.......FAILED at test 153

AIX 4.2      perlio   -Duseperlio -Duselongdouble -Dusethreads -Duseithreads
    op/magic..............FAILED at test 28
    pragma/overload.......FAILED at test 153

AIX 4.3      stdio    -Duseperlio -Dusemorebits -Dusethreads -Duseithreads
    op/numconvert.........FAILED at test 117

AIX 4.3      perlio   -Duseperlio -Dusemorebits -Dusethreads -Duseithreads
    op/numconvert.........FAILED at test 117

-- 
H.Merijn Brand           Amsterdam Perl Mongers (http://www.amsterdam.pm.org/)
using perl-5.005.03, 5.6.0, 5.6.1, 5.7.1 & 623 on HP-UX 10.20 & 11.00, AIX 4.2
   AIX 4.3, WinNT 4, Win2K pro & WinCE 2.11 often with Tk800.022 &/| DBD-Unify
ftp://ftp.funet.fi/pub/languages/perl/CPAN/authors/id/H/HM/HMBRAND/

#!/pro/bin/perl -w

my $p7    = "/pro/3gl/CPAN/perl-5.7.1";
my @hosts = qw(l1 k1 i2 ibm);
my (%rpt, @confs, %confs, $patch);

open RPT, "> $p7/mktest.rpt" or die "mktest.rpt: $!";
select RPT;

for my $host (@hosts) {
    my $perlio = "";
    my $conf   = "";
    open OUT, "</$host$p7/mktest.out" or next;
    for (<OUT>) {
	m/^\s*$/ and next;
	m/^-+$/  and next;
	if (m/^\s*Smoking patch (\d+)/) {
	    $patch = $1;
	    next;
	    }
	if (s/^Configuration:\s+//) {
	    s/-Dusedevel\s+//;
	    s/\s+-des//;
	    s/\s+$//;
	    $conf = $_;
	    $confs{$_}++ or push @confs, $conf;
	    next;
	    }
	if (m/PERLIO\s*=\s*(\w+)/) {
	    $perlio = $1;
	    next;
	    }
	if (m/^\s*All tests successful/) {
	    $rpt{$host}{$conf}{$perlio} = "O";
	    next;
	    }
	if (m/^\s*Skipped this configuration/) {
	    $rpt{$host}{$conf}{stdio}  = "o";
	    $rpt{$host}{$conf}{perlio} = "o";
	    next;
	    }
	if (m/^\s*Unable to build/) {
	    $rpt{$host}{$conf}{stdio}  = "-";
	    $rpt{$host}{$conf}{perlio} = "-";
	    next;
	    }
	if (m/FAILED/) {
	    push @{$rpt{$host}{$conf}{$perlio}}, $_;
	    next;
	    }
	}
    }

print <<EOH;
Automated smoke report for patch $patch

O = OK
o = OK (but skipped, cause tested in an earlier configuration)
- = not tested (cause unable to build)
F = Failure(s), extended report at the bottom
  left  letter for PERLIO = stdio,
  right letter for PERLIO = perlio

HP-UX HP-UX  AIX   AIX
11.00 10.20  4.3   4.2  Configuration
----- ----- ----- ----- --------------------------------------------------------------------
EOH

my @fail = ();
for my $conf (@confs) {
    for my $host (@hosts) {
	for my $perlio ("stdio", "perlio") {
	    my $res = $rpt{$host}{$conf}{$perlio};
	    if (ref $res) {
		print " F";
		push @fail, [ $host, $perlio, $conf, $res ];
		next;
		}
	    print " ", $res?$res:"?";
	    }
	print "  ";
	}
    print "$conf\n";
    }

my %os = (
    l1  => "HP-UX 11.00",
    k1  => "HP-UX 10.20",
    i2  => "AIX 4.3",
    ibm => "AIX 4.2",
    );
for my $ref (@fail) {
    printf "\n%-12s %-8s %s\n", $os{$ref->[0]}, @{$ref}[1,2];
    print @{$ref->[-1]};
    }