Re: killing a session

#!/usr/bin/env perl

use POE;

POE::Session->create(
	inline_states => {
		_start => sub {
			$_[KERNEL]->alias_set("ticker");
			$_[KERNEL]->delay(tick => 1);
		},
		tick => sub {
			_log("Ticker is working.");
			$_[KERNEL]->delay(tick => 1);
		},
		shutdown => sub {
			# Clean up our resources so we can exit cleanly.
			_log("Ticker is shutting down.  Please be patient...");
			$_[KERNEL]->delay(tick => undef);

			# Pretend shutdown takes some time.
			$_[KERNEL]->delay(faux_shutdown => 1);
		},
		faux_shutdown => sub {
			_log("Ticker has finished shutting down.");
		},
		_stop => sub {
			_log("Ticker session is being destroyed.");
		},
	},
);

POE::Session->create(
	inline_states => {
		_start => sub {
			$_[KERNEL]->alias_set("controller");
			$_[KERNEL]->sig(INT => "got_sigint");

			_log("Controller started.  Press Ctrl+C to exit.");
		},
		got_sigint => sub {
			_log("Controller caught sigint.  Shutting down...");
			$_[KERNEL]->post( ticker => "shutdown" );
			$_[KERNEL]->sig_handled();
		},
		_stop => sub {
			_log("Controller is being destroyed.");
		},
	},
);

POE::Kernel->run();
exit;

sub _log {
	my $message = join "", @_;
	print scalar(localtime), " - $message\n";
}