Re: Breathing
Jean-Michel Darrémont <jmdbrady-fBIn7JHAfCbUKx/[email protected]> Sun, 20 Jun 2004 13:57:10 +0200
| Newsgroups | gmane.comp.audio.csound.tekno |
|---|---|
| Message-ID | <BCFB4676.C38A%[email protected]> |
This is extracted from a Hans Mikelson's work called Valentin.orc that he posted for the Valentine's day. -- Jean-Michel Darrémont le 12/06/04 13:15, Brentt Newman à [email protected] a écrit : > Does anyone know a method to synthesize the sound of breathing or know > anywhere I can find information on the characteristics of it short of > analyzing it myself? Actually, I wouldn't mind analyzing it myself, as a > matter of fact I would love to, but unfortunately I don't have a microphone > and I can't find any sound files with it - I don't own any DVDs either or > else I could probably find some breathing in a movie. On second thought, if > anyone has a microphone and a FTP site, and wouldn't mind recording a couple > of deep breaths I would be most appreciative - but that's a lot to ask. > > Anyways can anyone have any useful information? > > _________________________________________________________________ > Watch the online reality show Mixed Messages with a friend and enter to win > a trip to NY > http://www.msnmessenger-download.click-url.com/go/onm00200497ave/direct/01/ > > _______________________________________________ > csoundtekno mailing list > [email protected] > > Subscribe, unsubscribe, change mailing list options: > http://plot.bek.no/mailman/listinfo/csoundtekno >
Breath.sco
(application/applefile, 436 B) - not displayed
Breath.sco
(text/plain, 1.5 KB)
; Sine Wave f1 0 16384 10 1 f19 0 1024 19 .5 .5 270 .5 f2 0 8192 7 -1 4096 1 4096 -1 ; Triangle Wave 1 ; Mixer Tables ; 3=FadeIn, 5=FadeOut, 6=Const1, 7=Const.5 f3 0 1024 -7 0 1024 1 ; UpSaw/FadeIn/PanRL f4 0 1024 -7 0 512 1 512 0 ; Tri/Pan RLR/Fade In&Out f5 0 1024 -7 1 1024 0 ; DnSaw/FadeOut/PanLR f6 0 1024 -7 1 1024 1 ; Const1/PanL f7 0 1024 -7 .5 1024 .5 ; Const.5/PanC f8 0 1024 -7 0 1024 0 ; Const0/PanR f9 0 1024 -7 0 256 1 768 1 ; Voice Amp f10 0 1024 -7 .5 256 .2 768 .8 ; Voice Pan CRL f11 0 1024 -7 .5 256 .8 768 .2 ; Voice Pan CLR ;--------------------------------------------------------------------------- ; Breathing ;--------------------------------------------------------------------------- f40 0 1024 -7 0 512 0 256 1 256 0 f41 0 1024 -7 0 128 1 384 0 512 0 f42 0 1024 -7 0 256 1.5 256 1.5 512 0 f42 25 1024 -7 0 256 1.5 768 2.5 f43 0 1024 -7 .3125 256 .3125 256 .625 512 .625 f43 25 1024 -7 10 256 10 256 10 256 .625 128 .3125 128 .3125 f46 0 1024 -7 .9375 256 .9375 256 1.875 512 1.875 f46 25 1024 -7 10 256 10 256 10 256 .9375 128 .625 128 .625 f44 0 1024 -7 0 356 0 64 1 64 0 604 0 f45 0 1024 -7 0 64 1 80 .7 64 0 816 0 f47 0 1024 -7 0 256 1 256 1 512 0 f47 25 1024 -7 0 256 4 768 1.5 f48 0 16384 10 1 .3 .1 0 .05 0 .1 ; Sta Dur Amp RateTable Wave1 Wave2 AmpTable i41 0 24 100 43 40 41 47 i41 25 24 100 43 40 41 47
Breath.orc
(application/applefile, 436 B) - not displayed
Breath.orc
(text/plain, 1 KB)
nchnls = 2
;---------------------------------------------------------------------------
; Breath
;---------------------------------------------------------------------------
instr 41
idur = p3
iamp = p4
irate = p5
iwave1 = p6
iwave2 = p7
iamptab = p8
adel1 init 0
adel2 init 0
krate oscili 1, 1/idur, irate
kamp1 oscili 1, krate, iwave1
kamp2 oscili 1, krate, iwave2
kamp3 oscili 1, 1/idur, iamptab
kosc1 oscil 20, .5, 1
kosc2 oscil 20, .5, 1, .25
kdel1 = kosc1+21
kdel2 = kosc2+21
anoise rand iamp/10
a1 reson anoise, 747, 200
a2 reson anoise, 1403, 500
a3 reson anoise, 3221, 500
a4 reson anoise, 5526, 600
a5 reson anoise, 300, 50
a6 reson anoise, 730, 100
a7 reson anoise, 1360, 150
a8 reson anoise, 3135, 300
aout1 = kamp1*(5*a1+4*a2+2*a3+a4)*kamp3
aout2 = kamp2*(a5+2*a6+4*a7+4*a8)*kamp3
adel1 delay aout1, .15
adel2 delay aout2, .15
outs adel1-.5*adel2, adel2-.5*adel1
endin