Re: 2-ish questions about Trigger/Duty/Demand

> 2 maj 2021 kl. 11:44 skrev [email protected]:
> 
> Dear all
> 
> I have 2 questions, from generic to specific:
> 
> 1) is there an amazing tutorial (Andrea/Eli-style), on poweruse of sample-accurate server-side triggering via Demand/Duty/Trigger - I am looking at ways of computing states on sequences via triggers like below and I wonder what is the best way
> 
> 2) in the following synth, 3 questions
> 
> ```
> (
> c = {arg t_go;
> 	OffsetOut.ar(0,
> 		TDuty.ar(
> 			Dgeom(TRand.ar(0.2,1,t_go),TRand.ar(0.7,0.9,t_go),4), 
> 			T2A.ar(t_go), 
> 			0.5);
> 	)
> }.play;
> )
> 
> c.set(\t_go,1)
> ```
> 
> 2.1) is there (what is) a better way to do the same trick (t_go sets states of my bouncer randomly, but in my real usage they will be computed.

maybe not better but a different approach...

(
c = {arg t_go;
	var dur= 1.5;
	var cur= TRand.kr(-6, 6, t_go);
	var num= 4;
	Changed.ar(EnvGen.ar(Env(#[0, 0, 1], [0, dur], cur), t_go, num).ceil)*0.5
}.play;
)

c.set(\t_go,1)

> 2.2) is there a way to load the synth without having an initial bounce? I cannot start the synth via language side and no, I cannot just start it when the first t_go happen. Sample accurate first action at first t_go, no before, not after :)

you can gate the first bounce with a SetResetFF...

(
c = {arg t_go;
	OffsetOut.ar(0,
		TDuty.ar(
			Dgeom(TRand.ar(0.2,1,t_go),TRand.ar(0.7,0.9,t_go),4),
			T2A.ar(t_go), 
			0.5*SetResetFF.kr(t_go))
	);
}.play;
)

c.set(\t_go,1)


another solution is to create the synth with newPaused and then start it running at the same time as the initial trigger...

(
SynthDef(\c, {arg t_go;
	OffsetOut.ar(0,
		TDuty.ar(
			Dgeom(TRand.ar(0.2,1,t_go),TRand.ar(0.7,0.9,t_go),4),
			T2A.ar(t_go), 
			0.5)
	);
}).add;
)

c= Synth.newPaused(\c);

c.run.set(\t_go,1)



> 2.3) why do I get 5 bounces when my Dgeom is set to 4

no idea
_f

  #|
     fredrikolofsson.com     musicalfieldsforever.com
  |#


_______________________________________________
sc-users mailing list

info (subscription, etc.): http://www.birmingham.ac.uk/facilities/ea-studios/research/supercollider/mailinglist.aspx
archive: http://www.listarc.bham.ac.uk/marchives/sc-users/
search: http://www.listarc.bham.ac.uk/lists/sc-users/search/