Re: Re: GCIC Fullscreen applications - Update

Example :
******************************
BCECMODE CSECT *
          BALR  12,0
          USING *,12
          LINEDIT TEXT='TYPE #CP EXT WHEN READY'
          MVC   ENPSWSV,88
          MVC   88(8),EIPSW
          MVC   134(2),=XL2'0000'
          LPSW  WAIT01
*        BC    *  <== Or try that instead
GO01     DS    0D
          MVC   88(8),ENPSWSV
          LM    2,3,OEPSW
          LINEDIT TEXT='IRPT : ........ ........',                      X
                SUB=(HEX,(2),HEX,(3)),RENT=NO
          XR    2,2
          ICM   2,B'0011',EXTCODE
          LINEDIT TEXT='EXT CODE : ....',SUB=(HEX,(2))
          XR    15,15
          BR    14
EINT     DS    0H
          MVC   OEPSW(8),24
          MVC   EXTCODE(2),134
          NI    25,B'11111101'
*	 MVC   28(4),=AL4(GO01) (in case 'B *' is done)
          LPSW  24
          DS    0D
WAIT01   DC    AL4(X'01020000'),AL4(GO01)
* WAIT01   DC    AL4(X'010A0000'),AL4(GO01) <= try this for EC mode PSW
EIPSW    DC    AL4(0),AL4(EINT)
OEPSW    DS    D
ENPSWSV  DS    D
EXTCODE  DS    H
          DS    0D
          LTORG
          END
******************************
LOAD FOO
G FOO ( SYSTEM
******************************
CP Q S
...
LINEDIT ON , TIMER REAL, ISAM OFF, ECMODE ON
...
Note : ECMODE *IS* ON
******************************
TYPE #CP EXT WHEN READY.

CP EXT
IRPT : 01020040 00020040.
EXT CODE : 0000.
*****************************
Ext Code untouched. Interrupt code IS in old PSW.. So, despite having CP 
SET ECMODE ON, this program behaves correctly with a BC mode PSW.

--Ivan