Bug in flux coupling element

Hello list,

I am  a teacher  of an  electrical engineering course  and I  am using
gnucap in my classes. I found a  problem while I was trying to show an
example of  the book "Microelectronics"  of Adel S. Sedra  and Kenneth
C. Smith.  The example is the circuit of figure 3.52.  The listing for
SPICE  simulation is given  in figure  D.1. I  adapted the  listing as
follows (only last three lines):

----------------------------------------------------------fig-3-52.ckt
** A Regulated Power Supply **

* zener diode subcircuit
.subckt diode_zener 1 2
* connections:      | |
*               anode |
*                katode
Ddirect  1 2 diode_1mA
Dreverse 2 4 diode_ideal
Vz0 4 3 DC 4.9V
Rz  1 3 10
* declaration of diode models
.model diode_1mA   D (Is=100pA n=1.679)
.model diode_ideal D (Is=100pA n=0.01)
.ends diode_zener

** Main Circuit **
* input AC voltage
Vac 1 0 sin(0 169V 60Hz)
Rs 1 2 0.5
* transformer with centre tap
Lp   2 0 10mH
Ls1  3 4 51uH
Ls2  4 5 51uH
K12 Lp  Ls1 0.999
K13 Lp  Ls2 0.999
K23 Ls1 Ls2 0.999
* isolation resistor
Risol  4 0 100Meg
* full-wave rectifier circuit
D1 3 6 D1N4148
D2 5 6 D1N4148
C 6 4 583uF
R 6 7 160
* zener diode
XZ1 4 7 diode_zener
* load
Rload 7 4 500
* diode model declaration
.model D1N4148 D (Is=0.1pA Rs=16 CJO=2p Tt=12n Bv=100 Ibv=0.1p)
** Desired analysis **
.OPTIONS ITL5=0
.TRAN 0.5ms 200ms 0ms 0.5ms UIC
.PRINT TRAN V(7,4) V(6,4)
.end
----------------------------------------------------------------------

For the  above file, the voltages  between 7 and  4, and 6 and  4, are
always 0. But, removing flux  coupling K23, the results are very close
to what we expect.   I tried to make coupling K23 equal  to 0:

K23 Ls1 Ls2 0.000

which is theoretically,  the same thing of removing  or commenting its
line, but it does not work: voltages were still equal to 0.

I installed gnucap from debian sarge. The initial message of gnucap:

$ gnucap
Gnucap 0.34
The Gnu Circuit Analysis Package
Never trust any version less than 1.0
Copyright 1982-2002, Albert Davis
Gnucap comes with ABSOLUTELY NO WARRANTY
This is free software, and you are welcome
to redistribute it under certain conditions
according to the GNU General Public License.
See the file "COPYING" for details.
gnucap> 

Thanks,

Betoes